mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-15 09:03:48 +00:00
e0b44a09b8
The latest release of libyamlcpp in nixpkgs does not build because it uses an older version of boost than the one in nixpkgs and therefore expects a particular header file which does not exist in the latest boost anymore. For this reason, a later (git) version of libyamlcpp is used here (which actually doesn't even require boost). The substituteInPlace in the prePatch phase is needed because libevdev places its headers in non-standard places, meaning Nix cannot normally find them. The `cut` command removes the first two "-I" characters from the output of `pkg-config`. This needs to be in the prePatch phase because otherwise Nix will patch these lines to `/var/empty`, meaning you would have less specific replacement (in case other lines are also patched to `/var/empty`). I wrote the patch. (I believe it is NixOS specific.)
62 lines
1.7 KiB
Nix
62 lines
1.7 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.interception-tools;
|
|
in {
|
|
options.services.interception-tools = {
|
|
enable = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = "Whether to enable the interception tools service.";
|
|
};
|
|
|
|
plugins = mkOption {
|
|
type = types.listOf types.package;
|
|
default = [ pkgs.interception-tools-plugins.caps2esc ];
|
|
description = ''
|
|
A list of interception tools plugins that will be made available to use
|
|
inside the udevmon configuration.
|
|
'';
|
|
};
|
|
|
|
udevmonConfig = mkOption {
|
|
type = types.either types.str types.path;
|
|
default = ''
|
|
- JOB: "intercept -g $DEVNODE | caps2esc | uinput -d $DEVNODE"
|
|
DEVICE:
|
|
EVENTS:
|
|
EV_KEY: [KEY_CAPSLOCK, KEY_ESC]
|
|
'';
|
|
example = ''
|
|
- JOB: "intercept -g $DEVNODE | y2z | x2y | uinput -d $DEVNODE"
|
|
DEVICE:
|
|
EVENTS:
|
|
EV_KEY: [KEY_X, KEY_Y]
|
|
'';
|
|
description = ''
|
|
String of udevmon YAML configuration, or path to a udevmon YAML
|
|
configuration file.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
systemd.services.interception-tools = {
|
|
description = "Interception tools";
|
|
path = [ pkgs.bash pkgs.interception-tools ] ++ cfg.plugins;
|
|
serviceConfig = {
|
|
ExecStart = ''
|
|
${pkgs.interception-tools}/bin/udevmon -c \
|
|
${if builtins.typeOf cfg.udevmonConfig == "path"
|
|
then cfg.udevmonConfig
|
|
else pkgs.writeText "udevmon.yaml" cfg.udevmonConfig}
|
|
'';
|
|
Nice = -20;
|
|
};
|
|
wantedBy = [ "multi-user.target" ];
|
|
};
|
|
};
|
|
}
|