mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-25 03:17:13 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
42 lines
1.2 KiB
Nix
42 lines
1.2 KiB
Nix
{ lib, fetchzip, buildGo123Module, nixosTests }:
|
|
|
|
buildGo123Module rec {
|
|
pname = "traefik";
|
|
version = "3.1.4";
|
|
|
|
# Archive with static assets for webui
|
|
src = fetchzip {
|
|
url = "https://github.com/traefik/traefik/releases/download/v${version}/traefik-v${version}.src.tar.gz";
|
|
hash = "sha256-e77PCMeN6Ck6hQ3Rx7MU4EL+f/1kpA2E+gVcISoUnf4=";
|
|
stripRoot = false;
|
|
};
|
|
|
|
vendorHash = "sha256-iYwA/y9AuHomyEckOyl4845lkQkeBAFDsGiZWESylqs=";
|
|
|
|
subPackages = [ "cmd/traefik" ];
|
|
|
|
preBuild = ''
|
|
GOOS= GOARCH= CGO_ENABLED=0 go generate
|
|
|
|
CODENAME=$(grep -Po "CODENAME \?=\s\K.+$" Makefile)
|
|
|
|
ldflags="-s"
|
|
ldflags+=" -w"
|
|
ldflags+=" -X github.com/traefik/traefik/v${lib.versions.major version}/pkg/version.Version=${version}"
|
|
ldflags+=" -X github.com/traefik/traefik/v${lib.versions.major version}/pkg/version.Codename=$CODENAME"
|
|
'';
|
|
|
|
doCheck = false;
|
|
|
|
passthru.tests = { inherit (nixosTests) traefik; };
|
|
|
|
meta = with lib; {
|
|
homepage = "https://traefik.io";
|
|
description = "Modern reverse proxy";
|
|
changelog = "https://github.com/traefik/traefik/raw/v${version}/CHANGELOG.md";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ vdemeester ];
|
|
mainProgram = "traefik";
|
|
};
|
|
}
|