mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-17 10:24:15 +00:00
f3bf2c9548
Semi-automatic update. These checks were done: - built on NixOS - ran `/nix/store/cikcvld2cd32if9qgc3ilvvb7iksds3c-gsm-1.0.17/bin/toast -h` got 0 exit code - ran `/nix/store/cikcvld2cd32if9qgc3ilvvb7iksds3c-gsm-1.0.17/bin/toast help` got 0 exit code - ran `/nix/store/cikcvld2cd32if9qgc3ilvvb7iksds3c-gsm-1.0.17/bin/tcat -h` got 0 exit code - ran `/nix/store/cikcvld2cd32if9qgc3ilvvb7iksds3c-gsm-1.0.17/bin/tcat help` got 0 exit code - ran `/nix/store/cikcvld2cd32if9qgc3ilvvb7iksds3c-gsm-1.0.17/bin/untoast -h` got 0 exit code - ran `/nix/store/cikcvld2cd32if9qgc3ilvvb7iksds3c-gsm-1.0.17/bin/untoast help` got 0 exit code - found 1.0.17 with grep in /nix/store/cikcvld2cd32if9qgc3ilvvb7iksds3c-gsm-1.0.17 - found 1.0.17 in filename of file in /nix/store/cikcvld2cd32if9qgc3ilvvb7iksds3c-gsm-1.0.17
54 lines
1.7 KiB
Nix
54 lines
1.7 KiB
Nix
{ stdenv, fetchurl
|
|
, staticSupport ? false # Compile statically (support for packages that look for the static object)
|
|
}:
|
|
|
|
let
|
|
inherit (stdenv) isDarwin;
|
|
inherit (stdenv.lib) optional optionalString;
|
|
in
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "gsm-${version}";
|
|
version = "1.0.17";
|
|
|
|
src = fetchurl {
|
|
url = "http://www.quut.com/gsm/${name}.tar.gz";
|
|
sha256 = "00bns0d4wwrvc60lj2w7wz4yk49q1f6rpdrwqzrxsha9d78mfnl5";
|
|
};
|
|
|
|
patchPhase = ''
|
|
# Fix include directory
|
|
sed -e 's,$(GSM_INSTALL_ROOT)/inc,$(GSM_INSTALL_ROOT)/include/gsm,' -i Makefile
|
|
'' + optionalString (!staticSupport) (
|
|
(if isDarwin then ''
|
|
# Build dylib on Darwin
|
|
sed -e 's,libgsm.a,libgsm.dylib,' -i Makefile
|
|
sed -e 's,$(AR) $(ARFLAGS) $(LIBGSM) $(GSM_OBJECTS),$(LD) -o $(LIBGSM) -dynamiclib -install_name $(GSM_INSTALL_ROOT)/$(LIBGSM) $(GSM_OBJECTS) -lc,' -i Makefile
|
|
'' else ''
|
|
# Build ELF shared object by default
|
|
sed -e 's,libgsm.a,libgsm.so,' -i Makefile
|
|
sed -e 's/$(AR) $(ARFLAGS) $(LIBGSM) $(GSM_OBJECTS)/$(LD) -shared -Wl,-soname,libgsm.so -o $(LIBGSM) $(GSM_OBJECTS) -lc/' -i Makefile
|
|
'') + ''
|
|
# Remove line that is unused when building shared libraries
|
|
sed -e 's,$(RANLIB) $(LIBGSM),,' -i Makefile
|
|
''
|
|
);
|
|
|
|
makeFlags = [
|
|
"SHELL=${stdenv.shell}"
|
|
"INSTALL_ROOT=$(out)"
|
|
] ++ optional stdenv.cc.isClang "CC=clang";
|
|
|
|
preInstall = "mkdir -p $out/{bin,lib,man/man1,man/man3,include/gsm}";
|
|
|
|
parallelBuild = false;
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Lossy speech compression codec";
|
|
homepage = http://www.quut.com/gsm/;
|
|
license = licenses.bsd2;
|
|
maintainers = with maintainers; [ codyopel raskin ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|