mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-23 18:37:02 +00:00
dadc7eb329
Whenever we create scripts that are installed to $out, we must use runtimeShell in order to get the shell that can be executed on the machine we create the package for. This is relevant for cross-compiling. The only use case for stdenv.shell are scripts that are executed as part of the build system. Usages in checkPhase are borderline however to decrease the likelyhood of people copying the wrong examples, I decided to use runtimeShell as well.
58 lines
1.8 KiB
Nix
58 lines
1.8 KiB
Nix
{ stdenv, fetchurl, glibc, libX11, runtimeShell, libGLU_combined }:
|
||
|
||
with stdenv.lib;
|
||
stdenv.mkDerivation {
|
||
name = "tibia-10.90";
|
||
|
||
src = fetchurl {
|
||
url = http://static.tibia.com/download/tibia1090.tgz;
|
||
sha256 = "11mkh2dynmbpay51yfaxm5dmcys3rnpk579s9ypfkhblsrchbkhx";
|
||
};
|
||
|
||
shell = stdenv.shell;
|
||
|
||
# These binaries come stripped already and trying to strip after the
|
||
# files are in $out/res and after patchelf just breaks them.
|
||
# Strangely it works if the files are in $out but then nix doesn't
|
||
# put them in our PATH. We set all the files to $out/res because
|
||
# we'll be using a wrapper to start the program which will go into
|
||
# $out/bin.
|
||
dontStrip = true;
|
||
|
||
installPhase = ''
|
||
mkdir -pv $out/res
|
||
cp -r * $out/res
|
||
|
||
patchelf --set-interpreter ${glibc.out}/lib/ld-linux.so.2 \
|
||
--set-rpath ${stdenv.lib.makeLibraryPath [ stdenv.cc.cc libX11 libGLU_combined ]} \
|
||
"$out/res/Tibia"
|
||
|
||
# We've patchelf'd the files. The main ‘Tibia’ binary is a bit
|
||
# dumb so it looks for ‘./Tibia.dat’. This requires us to be in
|
||
# the same directory as the file itself but that's very tedious,
|
||
# especially with nix which changes store hashes. Here we generate
|
||
# a simple wrapper that we put in $out/bin which will do the
|
||
# directory changing for us.
|
||
|
||
mkdir -pv $out/bin
|
||
|
||
# The wrapper script itself. We use $LD_LIBRARY_PATH for libGL.
|
||
cat << EOF > "$out/bin/Tibia"
|
||
#!${runtimeShell}
|
||
cd $out/res
|
||
${glibc.out}/lib/ld-linux.so.2 --library-path \$LD_LIBRARY_PATH ./Tibia "\$@"
|
||
EOF
|
||
|
||
chmod +x $out/bin/Tibia
|
||
|
||
'';
|
||
|
||
meta = {
|
||
description = "Top-down MMORPG set in a fantasy world";
|
||
homepage = http://tibia.com;
|
||
license = stdenv.lib.licenses.unfree;
|
||
platforms = ["i686-linux"];
|
||
maintainers = with stdenv.lib.maintainers; [ fuuzetsu ];
|
||
};
|
||
}
|