mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-25 23:20:55 +00:00
41 lines
1.2 KiB
Nix
41 lines
1.2 KiB
Nix
{ lib, stdenv, ocaml, findlib, dune_1, dune_2 }:
|
|
|
|
{ pname, version, buildInputs ? [], enableParallelBuilding ? true, ... }@args:
|
|
|
|
let Dune = if args.useDune2 or false then dune_2 else dune_1; in
|
|
|
|
if (args ? minimumOCamlVersion && ! lib.versionAtLeast ocaml.version args.minimumOCamlVersion) ||
|
|
(args ? minimalOCamlVersion && ! lib.versionAtLeast ocaml.version args.minimalOCamlVersion)
|
|
then throw "${pname}-${version} is not available for OCaml ${ocaml.version}"
|
|
else
|
|
|
|
stdenv.mkDerivation ({
|
|
|
|
inherit enableParallelBuilding;
|
|
|
|
buildPhase = ''
|
|
runHook preBuild
|
|
dune build -p ${pname} ''${enableParallelBuilding:+-j $NIX_BUILD_CORES}
|
|
runHook postBuild
|
|
'';
|
|
checkPhase = ''
|
|
runHook preCheck
|
|
dune runtest -p ${pname} ''${enableParallelBuilding:+-j $NIX_BUILD_CORES}
|
|
runHook postCheck
|
|
'';
|
|
installPhase = ''
|
|
runHook preInstall
|
|
dune install --prefix $out --libdir $OCAMLFIND_DESTDIR ${pname}
|
|
runHook postInstall
|
|
'';
|
|
|
|
} // (builtins.removeAttrs args [ "minimalOCamlVersion" ]) // {
|
|
|
|
name = "ocaml${ocaml.version}-${pname}-${version}";
|
|
|
|
buildInputs = [ ocaml Dune findlib ] ++ buildInputs;
|
|
|
|
meta = (args.meta or {}) // { platforms = args.meta.platforms or ocaml.meta.platforms; };
|
|
|
|
})
|