mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-15 00:54:46 +00:00
c1d24efd6a
As discussed in #10623, many R modules fail to build on Darwin without the libraries and compilers provided by these packages. For more detail, please see comment: https://github.com/NixOS/nixpkgs/pull/10623#issuecomment-172375342
55 lines
1.5 KiB
Nix
55 lines
1.5 KiB
Nix
{ stdenv, R, libcxx, xvfb_run, utillinux, Cocoa, Foundation, gettext, gfortran }:
|
|
|
|
{ name, buildInputs ? [], ... } @ attrs:
|
|
|
|
stdenv.mkDerivation ({
|
|
buildInputs = buildInputs ++ [R] ++
|
|
stdenv.lib.optionals attrs.requireX [utillinux xvfb_run] ++
|
|
stdenv.lib.optionals stdenv.isDarwin [Cocoa Foundation gettext gfortran];
|
|
|
|
NIX_CFLAGS_COMPILE =
|
|
stdenv.lib.optionalString stdenv.isDarwin "-I${libcxx}/include/c++/v1";
|
|
|
|
configurePhase = ''
|
|
runHook preConfigure
|
|
export R_LIBS_SITE="$R_LIBS_SITE''${R_LIBS_SITE:+:}$out/library"
|
|
runHook postConfigure
|
|
'';
|
|
|
|
buildPhase = ''
|
|
runHook preBuild
|
|
runHook postBuild
|
|
'';
|
|
|
|
installFlags = if attrs.doCheck or true then
|
|
[]
|
|
else
|
|
[ "--no-test-load" ];
|
|
|
|
rCommand = if attrs.requireX or false then
|
|
# Unfortunately, xvfb-run has a race condition even with -a option, so that
|
|
# we acquire a lock explicitly.
|
|
"flock ${xvfb_run} xvfb-run -a -e xvfb-error R"
|
|
else
|
|
"R";
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
mkdir -p $out/library
|
|
$rCommand CMD INSTALL $installFlags --configure-args="$configureFlags" -l $out/library .
|
|
runHook postInstall
|
|
'';
|
|
|
|
postFixup = ''
|
|
if test -e $out/nix-support/propagated-native-build-inputs; then
|
|
ln -s $out/nix-support/propagated-native-build-inputs $out/nix-support/propagated-user-env-packages
|
|
fi
|
|
'';
|
|
|
|
checkPhase = ''
|
|
# noop since R CMD INSTALL tests packages
|
|
'';
|
|
} // attrs // {
|
|
name = "r-" + name;
|
|
})
|