mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-25 03:17:13 +00:00
f5fa5fa4d6
* pkgs: refactor needless quoting of homepage meta attribute A lot of packages are needlessly quoting the homepage meta attribute (about 1400, 22%), this commit refactors all of those instances. * pkgs: Fixing some links that were wrongfully unquoted in the previous commit * Fixed some instances
75 lines
2.1 KiB
Nix
75 lines
2.1 KiB
Nix
{ stdenv, fetchFromGitHub, pkgconfig, python2Packages, makeWrapper
|
|
, bash, libsamplerate, libsndfile, readline, eigen, celt
|
|
|
|
# Optional Dependencies
|
|
, dbus ? null, libffado ? null, alsaLib ? null
|
|
, libopus ? null
|
|
|
|
# Extra options
|
|
, prefix ? ""
|
|
}:
|
|
|
|
with stdenv.lib;
|
|
let
|
|
inherit (python2Packages) python dbus-python;
|
|
shouldUsePkg = pkg: if pkg != null && stdenv.lib.any (x: x == stdenv.system) pkg.meta.platforms then pkg else null;
|
|
|
|
libOnly = prefix == "lib";
|
|
|
|
optDbus = shouldUsePkg dbus;
|
|
optPythonDBus = if libOnly then null else shouldUsePkg dbus-python;
|
|
optLibffado = if libOnly then null else shouldUsePkg libffado;
|
|
optAlsaLib = if libOnly then null else shouldUsePkg alsaLib;
|
|
optLibopus = shouldUsePkg libopus;
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
name = "${prefix}jack2-${version}";
|
|
version = "1.9.11-RC1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "jackaudio";
|
|
repo = "jack2";
|
|
rev = "v${version}";
|
|
sha256 = "0i708ar3ll5p8yj0h7ffg84nrn49ap47l2yy75rxyw30cyywhxp4";
|
|
};
|
|
|
|
nativeBuildInputs = [ pkgconfig python makeWrapper ];
|
|
buildInputs = [ python libsamplerate libsndfile readline eigen celt
|
|
optDbus optPythonDBus optLibffado optAlsaLib optLibopus
|
|
];
|
|
|
|
patchPhase = ''
|
|
substituteInPlace svnversion_regenerate.sh --replace /bin/bash ${bash}/bin/bash
|
|
'';
|
|
|
|
configurePhase = ''
|
|
python waf configure --prefix=$out \
|
|
${optionalString (optDbus != null) "--dbus"} \
|
|
--classic \
|
|
${optionalString (optLibffado != null) "--firewire"} \
|
|
${optionalString (optAlsaLib != null) "--alsa"} \
|
|
--autostart=${if (optDbus != null) then "dbus" else "classic"} \
|
|
'';
|
|
|
|
buildPhase = ''
|
|
python waf build
|
|
'';
|
|
|
|
installPhase = ''
|
|
python waf install
|
|
'' + (if libOnly then ''
|
|
rm -rf $out/{bin,share}
|
|
rm -rf $out/lib/{jack,libjacknet*,libjackserver*}
|
|
'' else ''
|
|
wrapProgram $out/bin/jack_control --set PYTHONPATH $PYTHONPATH
|
|
'');
|
|
|
|
meta = {
|
|
description = "JACK audio connection kit, version 2 with jackdbus";
|
|
homepage = http://jackaudio.org;
|
|
license = licenses.gpl2Plus;
|
|
platforms = platforms.unix;
|
|
maintainers = with maintainers; [ goibhniu wkennington ];
|
|
};
|
|
}
|