mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-13 16:15:30 +00:00
4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
50 lines
1.1 KiB
Nix
50 lines
1.1 KiB
Nix
{ lib, stdenv, fetchFromGitHub, python3Packages, help2man, installShellFiles }:
|
|
|
|
python3Packages.buildPythonApplication rec {
|
|
pname = "crudini";
|
|
version = "0.9.3";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "pixelb";
|
|
repo = "crudini";
|
|
rev = version;
|
|
sha256 = "0298hvg0fpk0m0bjpwryj3icksbckwqqsr9w1ain55wf5s0v24k3";
|
|
};
|
|
|
|
nativeBuildInputs = [ help2man installShellFiles ];
|
|
|
|
propagatedBuildInputs = with python3Packages; [ iniparse ];
|
|
|
|
postPatch = ''
|
|
substituteInPlace crudini-help \
|
|
--replace ./crudini $out/bin/crudini
|
|
substituteInPlace tests/test.sh \
|
|
--replace ..: $out/bin:
|
|
'';
|
|
|
|
postInstall = ''
|
|
# this just creates the man page
|
|
make all
|
|
|
|
install -Dm444 -t $out/share/doc/${pname} README EXAMPLES
|
|
installManPage *.1
|
|
'';
|
|
|
|
checkPhase = ''
|
|
runHook preCheck
|
|
|
|
pushd tests >/dev/null
|
|
bash ./test.sh
|
|
popd >/dev/null
|
|
|
|
runHook postCheck
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "A utility for manipulating ini files ";
|
|
homepage = "https://www.pixelbeat.org/programs/crudini/";
|
|
license = licenses.gpl2Only;
|
|
maintainers = with maintainers; [ peterhoeg ];
|
|
};
|
|
}
|