mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-27 08:01:14 +00:00
41bd6d2614
When testing WireGuard updates, I usually run the VM-tests with different kernels to make sure we're not introducing accidental regressions for e.g. older kernels. I figured that we should automate this process to ensure continuously that WireGuard works fine on several kernels. For now I decided to test the latest LTS version (5.4) and the latest kernel (currently 5.6). We can add more kernels in the future, however this seems to significantly slow down evaluation and time. The list can be customized by running a command like this: nix-build nixos/tests/wireguard --arg kernelVersionsToTest '["4.19"]' The `kernelPackages` argument in the tests is null by default to make sure that it's still possible to invoke the test-files directly. In that case the default kernel of NixOS (currently 5.4) is used.
75 lines
2.1 KiB
Nix
75 lines
2.1 KiB
Nix
{ kernelPackages ? null }:
|
|
import ../make-test-python.nix ({ pkgs, lib, ...} :
|
|
let
|
|
wg-snakeoil-keys = import ./snakeoil-keys.nix;
|
|
peer = (import ./make-peer.nix) { inherit lib; };
|
|
in
|
|
{
|
|
name = "wireguard";
|
|
meta = with pkgs.stdenv.lib.maintainers; {
|
|
maintainers = [ ma27 ];
|
|
};
|
|
|
|
nodes = {
|
|
peer0 = peer {
|
|
ip4 = "192.168.0.1";
|
|
ip6 = "fd00::1";
|
|
extraConfig = {
|
|
boot = lib.mkIf (kernelPackages != null) { inherit kernelPackages; };
|
|
networking.firewall.allowedUDPPorts = [ 23542 ];
|
|
networking.wireguard.interfaces.wg0 = {
|
|
ips = [ "10.23.42.1/32" "fc00::1/128" ];
|
|
listenPort = 23542;
|
|
|
|
inherit (wg-snakeoil-keys.peer0) privateKey;
|
|
|
|
peers = lib.singleton {
|
|
allowedIPs = [ "10.23.42.2/32" "fc00::2/128" ];
|
|
|
|
inherit (wg-snakeoil-keys.peer1) publicKey;
|
|
};
|
|
};
|
|
};
|
|
};
|
|
|
|
peer1 = peer {
|
|
ip4 = "192.168.0.2";
|
|
ip6 = "fd00::2";
|
|
extraConfig = {
|
|
boot = lib.mkIf (kernelPackages != null) { inherit kernelPackages; };
|
|
networking.wireguard.interfaces.wg0 = {
|
|
ips = [ "10.23.42.2/32" "fc00::2/128" ];
|
|
listenPort = 23542;
|
|
allowedIPsAsRoutes = false;
|
|
|
|
inherit (wg-snakeoil-keys.peer1) privateKey;
|
|
|
|
peers = lib.singleton {
|
|
allowedIPs = [ "0.0.0.0/0" "::/0" ];
|
|
endpoint = "192.168.0.1:23542";
|
|
persistentKeepalive = 25;
|
|
|
|
inherit (wg-snakeoil-keys.peer0) publicKey;
|
|
};
|
|
|
|
postSetup = let inherit (pkgs) iproute; in ''
|
|
${iproute}/bin/ip route replace 10.23.42.1/32 dev wg0
|
|
${iproute}/bin/ip route replace fc00::1/128 dev wg0
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
};
|
|
|
|
testScript = ''
|
|
start_all()
|
|
|
|
peer0.wait_for_unit("wireguard-wg0.service")
|
|
peer1.wait_for_unit("wireguard-wg0.service")
|
|
|
|
peer1.succeed("ping -c5 fc00::1")
|
|
peer1.succeed("ping -c5 10.23.42.1")
|
|
'';
|
|
}
|
|
)
|