mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-25 03:17:13 +00:00
ea34c61c0f
a5ac052dd3 changed the platforms for
nextpnr from 'linux' to 'all', but unfortunately nextpnr has not been
building anyway due to a missing OpenGL dependency.[1][2]
Restrict back to Linux for now. When a build fix happens, we can open it
up again.
[1] https://hydra.nixos.org/build/99106360
[1] https://hydra.nixos.org/eval/1538169
Signed-off-by: Austin Seipp <aseipp@pobox.com>
68 lines
1.9 KiB
Nix
68 lines
1.9 KiB
Nix
{ stdenv, fetchFromGitHub, cmake
|
|
, boost, python3, eigen
|
|
, icestorm, trellis
|
|
, llvmPackages
|
|
|
|
, enableGui ? true
|
|
, wrapQtAppsHook
|
|
, qtbase
|
|
}:
|
|
|
|
let
|
|
boostPython = boost.override { python = python3; enablePython = true; };
|
|
in
|
|
with stdenv; mkDerivation rec {
|
|
pname = "nextpnr";
|
|
version = "2019.08.31";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "yosyshq";
|
|
repo = "nextpnr";
|
|
rev = "c0b7379e8672b6263152d5e340e62f22179fdc8b";
|
|
sha256 = "174n962xiwyzy53cn192h9rq95h951k3xy6bs43p5ya592ai5mjh";
|
|
};
|
|
|
|
nativeBuildInputs
|
|
= [ cmake ]
|
|
++ (lib.optional enableGui wrapQtAppsHook);
|
|
buildInputs
|
|
= [ boostPython python3 eigen ]
|
|
++ (lib.optional enableGui qtbase)
|
|
++ (lib.optional stdenv.cc.isClang llvmPackages.openmp);
|
|
|
|
enableParallelBuilding = true;
|
|
cmakeFlags =
|
|
[ "-DARCH=generic;ice40;ecp5"
|
|
"-DICEBOX_ROOT=${icestorm}/share/icebox"
|
|
"-DTRELLIS_ROOT=${trellis}/share/trellis"
|
|
"-DPYTRELLIS_LIBDIR=${trellis}/lib/trellis"
|
|
"-DUSE_OPENMP=ON"
|
|
# warning: high RAM usage
|
|
"-DSERIALIZE_CHIPDB=OFF"
|
|
# use PyPy for icestorm if enabled
|
|
"-DPYTHON_EXECUTABLE=${icestorm.pythonInterp}"
|
|
] ++ (lib.optional (!enableGui) "-DBUILD_GUI=OFF");
|
|
|
|
# Fix the version number. This is a bit stupid (and fragile) in practice
|
|
# but works ok. We should probably make this overrideable upstream.
|
|
patchPhase = with builtins; ''
|
|
substituteInPlace ./CMakeLists.txt \
|
|
--replace 'git log -1 --format=%h' 'echo ${substring 0 11 src.rev}'
|
|
'';
|
|
|
|
|
|
postFixup = lib.optionalString enableGui ''
|
|
wrapQtApp $out/bin/nextpnr-generic
|
|
wrapQtApp $out/bin/nextpnr-ice40
|
|
wrapQtApp $out/bin/nextpnr-ecp5
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Place and route tool for FPGAs";
|
|
homepage = https://github.com/yosyshq/nextpnr;
|
|
license = licenses.isc;
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ thoughtpolice emily ];
|
|
};
|
|
}
|