mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-09-11 15:08:33 +01:00
53 lines
1.2 KiB
Nix
53 lines
1.2 KiB
Nix
{ stdenv, fetchurl, makeWrapper
|
|
, xorg, imlib2, libjpeg, libpng
|
|
, curl, libexif, perlPackages }:
|
|
|
|
with stdenv.lib;
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "feh-${version}";
|
|
version = "2.19";
|
|
|
|
src = fetchurl {
|
|
url = "http://feh.finalrewind.org/${name}.tar.bz2";
|
|
sha256 = "1sfhr6628xpj9p6bqihdq35y139x2gmrpydjlrwsl1rs77c2bgnf";
|
|
};
|
|
|
|
outputs = [ "out" "man" "doc" ];
|
|
|
|
nativeBuildInputs = [ makeWrapper xorg.libXt ]
|
|
++ optionals doCheck [ perlPackages.TestCommand perlPackages.TestHarness ];
|
|
|
|
buildInputs = [ xorg.libX11 xorg.libXinerama imlib2 libjpeg libpng curl libexif ];
|
|
|
|
preBuild = ''
|
|
makeFlags="PREFIX=$out exif=1"
|
|
'';
|
|
|
|
postBuild = ''
|
|
pushd man
|
|
make
|
|
popd
|
|
'';
|
|
|
|
postInstall = ''
|
|
wrapProgram "$out/bin/feh" --prefix PATH : "${libjpeg.bin}/bin" \
|
|
--add-flags '--theme=feh'
|
|
install -D -m 644 man/*.1 $out/share/man/man1
|
|
'';
|
|
|
|
checkPhase = ''
|
|
PERL5LIB="${perlPackages.TestCommand}/lib/perl5/site_perl" make test
|
|
'';
|
|
|
|
doCheck = true;
|
|
|
|
meta = {
|
|
description = "A light-weight image viewer";
|
|
homepage = https://derf.homelinux.org/projects/feh/;
|
|
license = licenses.mit;
|
|
maintainers = [ maintainers.viric ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|