mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-25 15:11:35 +00:00
da19c34d0f
This continues #23374, which always kept around both attributes, by always including both propagated files: `propgated-native-build-inputs` and `propagated-build-inputs`. `nativePkgs` and `crossPkgs` are still defined as before, however, so this change should only barely observable. This is an incremental step to fully keeping the dependencies separate in all cases.
142 lines
5 KiB
Nix
142 lines
5 KiB
Nix
/*
|
|
|
|
# New packages
|
|
|
|
READ THIS FIRST
|
|
|
|
This module is for official packages in KDE Plasma 5. All available packages are
|
|
listed in `./srcs.nix`, although a few are not yet packaged in Nixpkgs (see
|
|
below).
|
|
|
|
IF YOUR PACKAGE IS NOT LISTED IN `./srcs.nix`, IT DOES NOT GO HERE.
|
|
|
|
Many of the packages released upstream are not yet built in Nixpkgs due to lack
|
|
of demand. To add a Nixpkgs build for an upstream package, copy one of the
|
|
existing packages here and modify it as necessary.
|
|
|
|
# Updates
|
|
|
|
1. Update the URL in `./fetch.sh`.
|
|
2. Run `./maintainers/scripts/fetch-kde-qt.sh pkgs/desktops/plasma-5`
|
|
from the top of the Nixpkgs tree.
|
|
3. Use `nox-review wip` to check that everything builds.
|
|
4. Commit the changes and open a pull request.
|
|
|
|
*/
|
|
|
|
{
|
|
libsForQt5, lib, fetchurl,
|
|
gconf,
|
|
debug ? false,
|
|
}:
|
|
|
|
let
|
|
srcs = import ./srcs.nix {
|
|
inherit fetchurl;
|
|
mirror = "mirror://kde";
|
|
};
|
|
|
|
mkDerivation = libsForQt5.callPackage ({ mkDerivation }: mkDerivation) {};
|
|
|
|
packages = self: with self;
|
|
let
|
|
|
|
propagate = out:
|
|
let setupHook = { writeScript }:
|
|
writeScript "setup-hook" ''
|
|
if [ "$hookName" != postHook ]; then
|
|
postHooks+=("source @dev@/nix-support/setup-hook")
|
|
else
|
|
# Propagate $${out} output
|
|
propagatedUserEnvPkgs="$propagatedUserEnvPkgs @${out}@"
|
|
|
|
if [ -z "$outputDev" ]; then
|
|
echo "error: \$outputDev is unset!" >&2
|
|
exit 1
|
|
fi
|
|
|
|
# Propagate $dev so that this setup hook is propagated
|
|
# But only if there is a separate $dev output
|
|
if [ "$outputDev" != out ]; then
|
|
propagatedBuildInputs="$propagatedBuildInputs @dev@"
|
|
fi
|
|
fi
|
|
'';
|
|
in callPackage setupHook {};
|
|
|
|
propagateBin = propagate "bin";
|
|
|
|
callPackage = self.newScope {
|
|
inherit propagate propagateBin;
|
|
|
|
mkDerivation = args:
|
|
let
|
|
inherit (args) name;
|
|
sname = args.sname or name;
|
|
inherit (srcs."${sname}") src version;
|
|
|
|
outputs = args.outputs or [ "out" ];
|
|
hasBin = lib.elem "bin" outputs;
|
|
hasDev = lib.elem "dev" outputs;
|
|
|
|
defaultSetupHook = if hasBin && hasDev then propagateBin else null;
|
|
setupHook = args.setupHook or defaultSetupHook;
|
|
|
|
meta = {
|
|
license = with lib.licenses; [
|
|
lgpl21Plus lgpl3Plus bsd2 mit gpl2Plus gpl3Plus fdl12
|
|
];
|
|
platforms = lib.platforms.linux;
|
|
maintainers = with lib.maintainers; [ ttuegel ];
|
|
homepage = http://www.kde.org;
|
|
} // (args.meta or {});
|
|
in
|
|
mkDerivation (args // {
|
|
name = "${name}-${version}";
|
|
inherit meta outputs setupHook src;
|
|
});
|
|
};
|
|
|
|
in {
|
|
bluedevil = callPackage ./bluedevil.nix {};
|
|
breeze-gtk = callPackage ./breeze-gtk.nix {};
|
|
breeze-qt4 = callPackage ./breeze-qt4.nix {};
|
|
breeze-qt5 = callPackage ./breeze-qt5.nix {};
|
|
breeze-grub = callPackage ./breeze-grub.nix {};
|
|
breeze-plymouth = callPackage ./breeze-plymouth {};
|
|
kactivitymanagerd = callPackage ./kactivitymanagerd.nix {};
|
|
kde-cli-tools = callPackage ./kde-cli-tools.nix {};
|
|
kde-gtk-config = callPackage ./kde-gtk-config {};
|
|
kdecoration = callPackage ./kdecoration.nix {};
|
|
kdeplasma-addons = callPackage ./kdeplasma-addons.nix {};
|
|
kgamma5 = callPackage ./kgamma5.nix {};
|
|
khotkeys = callPackage ./khotkeys.nix {};
|
|
kinfocenter = callPackage ./kinfocenter.nix {};
|
|
kmenuedit = callPackage ./kmenuedit.nix {};
|
|
kscreen = callPackage ./kscreen.nix {};
|
|
kscreenlocker = callPackage ./kscreenlocker.nix {};
|
|
ksshaskpass = callPackage ./ksshaskpass.nix {};
|
|
ksysguard = callPackage ./ksysguard.nix {};
|
|
kwallet-pam = callPackage ./kwallet-pam.nix {};
|
|
kwayland-integration = callPackage ./kwayland-integration.nix {};
|
|
kwin = callPackage ./kwin {};
|
|
kwrited = callPackage ./kwrited.nix {};
|
|
libkscreen = callPackage ./libkscreen {};
|
|
libksysguard = callPackage ./libksysguard {};
|
|
milou = callPackage ./milou.nix {};
|
|
oxygen = callPackage ./oxygen.nix {};
|
|
plasma-desktop = callPackage ./plasma-desktop {};
|
|
plasma-integration = callPackage ./plasma-integration.nix {};
|
|
plasma-nm = callPackage ./plasma-nm {};
|
|
plasma-pa = callPackage ./plasma-pa.nix { inherit gconf; };
|
|
plasma-vault = callPackage ./plasma-vault {};
|
|
plasma-workspace = callPackage ./plasma-workspace {};
|
|
plasma-workspace-wallpapers = callPackage ./plasma-workspace-wallpapers.nix {};
|
|
polkit-kde-agent = callPackage ./polkit-kde-agent.nix {};
|
|
powerdevil = callPackage ./powerdevil.nix {};
|
|
sddm-kcm = callPackage ./sddm-kcm.nix {};
|
|
systemsettings = callPackage ./systemsettings.nix {};
|
|
};
|
|
in
|
|
lib.makeScope libsForQt5.newScope packages
|