mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-25 03:17:13 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
72 lines
1.7 KiB
Nix
72 lines
1.7 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
buildPostgresqlExtension,
|
|
fetchFromGitHub,
|
|
perl,
|
|
perlPackages,
|
|
postgresql,
|
|
postgresqlTestHook,
|
|
which,
|
|
}:
|
|
|
|
buildPostgresqlExtension (finalAttrs: {
|
|
pname = "pgtap";
|
|
version = "1.3.3";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "theory";
|
|
repo = "pgtap";
|
|
rev = "v${finalAttrs.version}";
|
|
sha256 = "sha256-YgvfLGF7pLVcCKD66NnWAydDxtoYHH1DpLiYTEKHJ0E=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
postgresql
|
|
perl
|
|
perlPackages.TAPParserSourceHandlerpgTAP
|
|
which
|
|
];
|
|
|
|
passthru.tests.extension = stdenv.mkDerivation {
|
|
name = "pgtap-test";
|
|
dontUnpack = true;
|
|
doCheck = true;
|
|
nativeCheckInputs = [
|
|
postgresqlTestHook
|
|
(postgresql.withPackages (_: [ finalAttrs.finalPackage ]))
|
|
];
|
|
passAsFile = [ "sql" ];
|
|
sql = ''
|
|
CREATE EXTENSION pgtap;
|
|
|
|
BEGIN;
|
|
SELECT plan(1);
|
|
SELECT pass('Test passed');
|
|
SELECT * FROM finish();
|
|
ROLLBACK;
|
|
'';
|
|
failureHook = "postgresqlStop";
|
|
checkPhase = ''
|
|
runHook preCheck
|
|
psql -a -v ON_ERROR_STOP=1 -f $sqlPath
|
|
runHook postCheck
|
|
'';
|
|
installPhase = "touch $out";
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Unit testing framework for PostgreSQL";
|
|
longDescription = ''
|
|
pgTAP is a unit testing framework for PostgreSQL written in PL/pgSQL and PL/SQL.
|
|
It includes a comprehensive collection of TAP-emitting assertion functions,
|
|
as well as the ability to integrate with other TAP-emitting test frameworks.
|
|
It can also be used in the xUnit testing style.
|
|
'';
|
|
maintainers = with maintainers; [ willibutz ];
|
|
homepage = "https://pgtap.org";
|
|
inherit (postgresql.meta) platforms;
|
|
license = licenses.mit;
|
|
};
|
|
})
|