mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-22 13:41:26 +00:00
2e75a7b516
Before this change `man 5 configuration.nix` would only show options of modules in the `baseModules` set, which consists only of the list of modules in `nixos/modules/module-list.nix` With this change applied and `documentation.nixos.includeAllModules` option enabled all modules included in `configuration.nix` file will be used instead. This makes configurations with custom modules self-documenting. It also means that importing non-`baseModules` modules like `gce.nix` or `azure.nix` will make their documentation available in `man 5 configuration.nix`. `documentation.nixos.includeAllModules` is currently set to `false` by default as enabling it usually uncovers bugs and prevents evaluation. It should be set to `true` in a release or two. This was originally implemented in #47177, edited for more configurability, documented and rebased onto master by @oxij.
68 lines
2.3 KiB
Nix
68 lines
2.3 KiB
Nix
# From an end-user configuration file (`configuration.nix'), build a NixOS
|
|
# configuration object (`config') from which we can retrieve option
|
|
# values.
|
|
|
|
# !!! Please think twice before adding to this argument list!
|
|
# Ideally eval-config.nix would be an extremely thin wrapper
|
|
# around lib.evalModules, so that modular systems that have nixos configs
|
|
# as subcomponents (e.g. the container feature, or nixops if network
|
|
# expressions are ever made modular at the top level) can just use
|
|
# types.submodule instead of using eval-config.nix
|
|
{ # !!! system can be set modularly, would be nice to remove
|
|
system ? builtins.currentSystem
|
|
, # !!! is this argument needed any more? The pkgs argument can
|
|
# be set modularly anyway.
|
|
pkgs ? null
|
|
, # !!! what do we gain by making this configurable?
|
|
baseModules ? import ../modules/module-list.nix
|
|
, # !!! See comment about args in lib/modules.nix
|
|
extraArgs ? {}
|
|
, # !!! See comment about args in lib/modules.nix
|
|
specialArgs ? {}
|
|
, modules
|
|
, # !!! See comment about check in lib/modules.nix
|
|
check ? true
|
|
, prefix ? []
|
|
, lib ? import ../../lib
|
|
}:
|
|
|
|
let extraArgs_ = extraArgs; pkgs_ = pkgs;
|
|
extraModules = let e = builtins.getEnv "NIXOS_EXTRA_MODULE_PATH";
|
|
in if e == "" then [] else [(import e)];
|
|
in
|
|
|
|
let
|
|
pkgsModule = rec {
|
|
_file = ./eval-config.nix;
|
|
key = _file;
|
|
config = {
|
|
# Explicit `nixpkgs.system` or `nixpkgs.localSystem` should override
|
|
# this. Since the latter defaults to the former, the former should
|
|
# default to the argument. That way this new default could propagate all
|
|
# they way through, but has the last priority behind everything else.
|
|
nixpkgs.system = lib.mkDefault system;
|
|
_module.args.pkgs = lib.mkIf (pkgs_ != null) (lib.mkForce pkgs_);
|
|
};
|
|
};
|
|
|
|
in rec {
|
|
|
|
# Merge the option definitions in all modules, forming the full
|
|
# system configuration.
|
|
inherit (lib.evalModules {
|
|
inherit prefix check;
|
|
modules = baseModules ++ extraModules ++ [ pkgsModule ] ++ modules;
|
|
args = extraArgs;
|
|
specialArgs =
|
|
{ modulesPath = builtins.toString ../modules; } // specialArgs;
|
|
}) config options;
|
|
|
|
# These are the extra arguments passed to every module. In
|
|
# particular, Nixpkgs is passed through the "pkgs" argument.
|
|
extraArgs = extraArgs_ // {
|
|
inherit baseModules extraModules modules;
|
|
};
|
|
|
|
inherit (config._module.args) pkgs;
|
|
}
|