mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-21 13:10:33 +00:00
dadc7eb329
Whenever we create scripts that are installed to $out, we must use runtimeShell in order to get the shell that can be executed on the machine we create the package for. This is relevant for cross-compiling. The only use case for stdenv.shell are scripts that are executed as part of the build system. Usages in checkPhase are borderline however to decrease the likelyhood of people copying the wrong examples, I decided to use runtimeShell as well.
65 lines
1.8 KiB
Nix
65 lines
1.8 KiB
Nix
{ stdenv, ncurses, buildGoPackage, fetchFromGitHub, writeText, runtimeShell }:
|
|
|
|
buildGoPackage rec {
|
|
name = "fzf-${version}";
|
|
version = "0.17.5";
|
|
rev = "${version}";
|
|
|
|
goPackagePath = "github.com/junegunn/fzf";
|
|
|
|
src = fetchFromGitHub {
|
|
inherit rev;
|
|
owner = "junegunn";
|
|
repo = "fzf";
|
|
sha256 = "04kalm25sn5k24nrdmbkafp4zvxpm2l3rxchvccl0kz0j3szh62z";
|
|
};
|
|
|
|
outputs = [ "bin" "out" "man" ];
|
|
|
|
fishHook = writeText "load-fzf-keybindings.fish" "fzf_key_bindings";
|
|
|
|
buildInputs = [ ncurses ];
|
|
|
|
goDeps = ./deps.nix;
|
|
|
|
patchPhase = ''
|
|
sed -i -e "s|expand('<sfile>:h:h')|'$bin'|" plugin/fzf.vim
|
|
|
|
# Original and output files can't be the same
|
|
if cmp -s $src/plugin/fzf.vim plugin/fzf.vim; then
|
|
echo "Vim plugin patch not applied properly. Aborting" && \
|
|
exit 1
|
|
fi
|
|
'';
|
|
|
|
preInstall = ''
|
|
mkdir -p $bin/share/fish/vendor_functions.d $bin/share/fish/vendor_conf.d
|
|
cp $src/shell/key-bindings.fish $bin/share/fish/vendor_functions.d/fzf_key_bindings.fish
|
|
cp ${fishHook} $bin/share/fish/vendor_conf.d/load-fzf-key-bindings.fish
|
|
'';
|
|
|
|
postInstall = ''
|
|
cp $src/bin/fzf-tmux $bin/bin
|
|
mkdir -p $man/share/man
|
|
cp -r $src/man/man1 $man/share/man
|
|
mkdir -p $out/share/vim-plugins/${name}
|
|
cp -r $src/plugin $out/share/vim-plugins/${name}
|
|
|
|
cp -R $src/shell $bin/share/fzf
|
|
cat <<SCRIPT > $bin/bin/fzf-share
|
|
#!${runtimeShell}
|
|
# Run this script to find the fzf shared folder where all the shell
|
|
# integration scripts are living.
|
|
echo $bin/share/fzf
|
|
SCRIPT
|
|
chmod +x $bin/bin/fzf-share
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = https://github.com/junegunn/fzf;
|
|
description = "A command-line fuzzy finder written in Go";
|
|
license = licenses.mit;
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|