mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-09-11 15:08:33 +01:00
28598c01e7
Firefox requires new version of the icu to build: ``` checking for icu-i18n >= 58.1... Requested 'icu-i18n >= 58.1' but version of icu-i18n is 57.1 configure: error: Library requirements (icu-i18n >= 58.1) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them. ```
65 lines
1.7 KiB
Nix
65 lines
1.7 KiB
Nix
{ stdenv, fetchurl, fetchpatch, fixDarwinDylibNames }:
|
|
|
|
let
|
|
pname = "icu4c";
|
|
version = "58.2";
|
|
in
|
|
stdenv.mkDerivation ({
|
|
name = pname + "-" + version;
|
|
|
|
src = fetchurl {
|
|
url = "http://download.icu-project.org/files/${pname}/${version}/${pname}-"
|
|
+ (stdenv.lib.replaceChars ["."] ["_"] version) + "-src.tgz";
|
|
sha256 = "036shcb3f8bm1lynhlsb4kpjm9s9c2vdiir01vg216rs2l8482ib";
|
|
};
|
|
|
|
outputs = [ "out" "dev" ];
|
|
outputBin = "dev";
|
|
|
|
# FIXME: This fixes dylib references in the dylibs themselves, but
|
|
# not in the programs in $out/bin.
|
|
buildInputs = stdenv.lib.optional stdenv.isDarwin fixDarwinDylibNames;
|
|
|
|
postUnpack = ''
|
|
sourceRoot=''${sourceRoot}/source
|
|
echo Source root reset to ''${sourceRoot}
|
|
'';
|
|
|
|
# This pre/postPatch shenanigans is to handle that the patches expect
|
|
# to be outside of `source`.
|
|
prePatch = ''
|
|
pushd ..
|
|
'';
|
|
postPatch = ''
|
|
popd
|
|
'';
|
|
|
|
patches = [
|
|
];
|
|
|
|
preConfigure = ''
|
|
sed -i -e "s|/bin/sh|${stdenv.shell}|" configure
|
|
'';
|
|
|
|
configureFlags = "--disable-debug" +
|
|
stdenv.lib.optionalString (stdenv.isFreeBSD || stdenv.isDarwin) " --enable-rpath";
|
|
|
|
# remove dependency on bootstrap-tools in early stdenv build
|
|
postInstall = stdenv.lib.optionalString stdenv.isDarwin ''
|
|
sed -i 's/INSTALL_CMD=.*install/INSTALL_CMD=install/' $out/lib/icu/${version}/pkgdata.inc
|
|
'';
|
|
|
|
postFixup = ''moveToOutput lib/icu "$dev" '';
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Unicode and globalization support library";
|
|
homepage = http://site.icu-project.org/;
|
|
maintainers = with maintainers; [ raskin urkud ];
|
|
platforms = platforms.all;
|
|
};
|
|
} // (if stdenv.isArm then {
|
|
patches = [ ./0001-Disable-LDFLAGSICUDT-for-Linux.patch ];
|
|
} else {}))
|