mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-09-11 15:08:33 +01:00
aff1f4ab94
The following parameters are now available:
* hardeningDisable
To disable specific hardening flags
* hardeningEnable
To enable specific hardening flags
Only the cc-wrapper supports this right now, but these may be reused by
other wrappers, builders or setup hooks.
cc-wrapper supports the following flags:
* fortify
* stackprotector
* pie (disabled by default)
* pic
* strictoverflow
* format
* relro
* bindnow
65 lines
2.1 KiB
Nix
65 lines
2.1 KiB
Nix
{ stdenv, fetchurl, pkgconfig, libpng, libjpeg, expat, libXaw
|
|
, yacc, libtool, fontconfig, pango, gd, xorg, gts, gettext, cairo
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
version = "2.32.0";
|
|
name = "graphviz-${version}";
|
|
|
|
src = fetchurl {
|
|
url = "http://www.graphviz.org/pub/graphviz/ARCHIVE/${name}.tar.gz";
|
|
sha256 = "0ym7lw3xnkcgbk32vfmm3329xymca60gzn90rq6dv8887qqv4lyq";
|
|
};
|
|
|
|
buildInputs =
|
|
[ pkgconfig libpng libjpeg expat libXaw yacc libtool fontconfig
|
|
pango gd gts
|
|
] ++ stdenv.lib.optionals (xorg != null) [ xorg.xlibsWrapper xorg.libXrender ]
|
|
++ stdenv.lib.optional (stdenv.system == "x86_64-darwin") gettext;
|
|
|
|
CPPFLAGS = stdenv.lib.optionalString (stdenv.system == "x86_64-darwin") "-I${cairo}/include/cairo";
|
|
|
|
configureFlags =
|
|
[ "--with-pngincludedir=${libpng}/include"
|
|
"--with-pnglibdir=${libpng}/lib"
|
|
"--with-jpegincludedir=${libjpeg}/include"
|
|
"--with-jpeglibdir=${libjpeg}/lib"
|
|
"--with-expatincludedir=${expat}/include"
|
|
"--with-expatlibdir=${expat}/lib"
|
|
"--with-cgraph=no"
|
|
"--with-sparse=no"
|
|
]
|
|
++ stdenv.lib.optional (xorg == null) "--without-x";
|
|
|
|
hardeningDisable = [ "fortify" ];
|
|
|
|
preBuild = ''
|
|
sed -e 's@am__append_5 *=.*@am_append_5 =@' -i lib/gvc/Makefile
|
|
'';
|
|
|
|
# "command -v" is POSIX, "which" is not
|
|
postInstall = ''
|
|
sed -i 's|`which lefty`|"'$out'/bin/lefty"|' $out/bin/dotty
|
|
sed -i 's|which|command -v|' $out/bin/vimdot
|
|
'';
|
|
|
|
meta = {
|
|
homepage = "http://www.graphviz.org/";
|
|
description = "Open source graph visualization software";
|
|
|
|
longDescription = ''
|
|
Graphviz is open source graph visualization software. Graph
|
|
visualization is a way of representing structural information as
|
|
diagrams of abstract graphs and networks. It has important
|
|
applications in networking, bioinformatics, software engineering,
|
|
database and web design, machine learning, and in visual
|
|
interfaces for other technical domains.
|
|
'';
|
|
|
|
hydraPlatforms = stdenv.lib.platforms.linux ++ stdenv.lib.platforms.darwin;
|
|
maintainers = with stdenv.lib.maintainers; [ simons bjornfor raskin ];
|
|
inherit version;
|
|
branch = "2.32";
|
|
};
|
|
}
|