mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-24 19:08:30 +00:00
f5fa5fa4d6
* pkgs: refactor needless quoting of homepage meta attribute A lot of packages are needlessly quoting the homepage meta attribute (about 1400, 22%), this commit refactors all of those instances. * pkgs: Fixing some links that were wrongfully unquoted in the previous commit * Fixed some instances
84 lines
2.7 KiB
Nix
84 lines
2.7 KiB
Nix
{ stdenv, lib, fetchurl, pkgconfig, audiofile
|
|
, openglSupport ? false, mesa_noglu
|
|
, alsaSupport ? true, alsaLib
|
|
, x11Support ? true, libICE, libXi, libXScrnSaver, libXcursor, libXinerama, libXext, libXxf86vm, libXrandr
|
|
, dbusSupport ? false, dbus
|
|
, udevSupport ? false, udev
|
|
, ibusSupport ? false, ibus
|
|
, pulseaudioSupport ? true, libpulseaudio
|
|
, AudioUnit, Cocoa, CoreAudio, CoreServices, ForceFeedback, OpenGL
|
|
}:
|
|
|
|
# OSS is no longer supported, for it's much crappier than ALSA and
|
|
# PulseAudio.
|
|
assert !stdenv.isDarwin -> alsaSupport || pulseaudioSupport;
|
|
|
|
assert openglSupport -> (stdenv.isDarwin || mesa_noglu != null && x11Support);
|
|
|
|
let
|
|
configureFlagsFun = attrs: [
|
|
"--disable-oss" "--disable-x11-shared"
|
|
"--disable-pulseaudio-shared" "--disable-alsa-shared"
|
|
] ++ lib.optional alsaSupport "--with-alsa-prefix=${attrs.alsaLib.out}/lib"
|
|
++ lib.optional (!x11Support) "--without-x";
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
name = "SDL2-${version}";
|
|
version = "2.0.5";
|
|
|
|
src = fetchurl {
|
|
url = "http://www.libsdl.org/release/${name}.tar.gz";
|
|
sha256 = "11c75qj1qxmx67iwkvf9z4x69phk301pdn86zzr6jncnap7kh824";
|
|
};
|
|
|
|
outputs = [ "out" "dev" ];
|
|
|
|
patches = [ ./find-headers.patch ];
|
|
|
|
nativeBuildInputs = [ pkgconfig ];
|
|
|
|
# Since `libpulse*.la' contain `-lgdbm', PulseAudio must be propagated.
|
|
propagatedBuildInputs = lib.optionals x11Support [ libICE libXi libXScrnSaver libXcursor libXinerama libXext libXrandr libXxf86vm ] ++
|
|
lib.optional pulseaudioSupport libpulseaudio;
|
|
|
|
buildInputs = [ audiofile ] ++
|
|
lib.optional openglSupport mesa_noglu ++
|
|
lib.optional alsaSupport alsaLib ++
|
|
lib.optional dbusSupport dbus ++
|
|
lib.optional udevSupport udev ++
|
|
lib.optional ibusSupport ibus ++
|
|
lib.optionals stdenv.isDarwin [ AudioUnit Cocoa CoreAudio CoreServices ForceFeedback OpenGL ];
|
|
|
|
# https://bugzilla.libsdl.org/show_bug.cgi?id=1431
|
|
dontDisableStatic = true;
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
# XXX: By default, SDL wants to dlopen() PulseAudio, in which case
|
|
# we must arrange to add it to its RPATH; however, `patchelf' seems
|
|
# to fail at doing this, hence `--disable-pulseaudio-shared'.
|
|
configureFlags = configureFlagsFun { inherit alsaLib; };
|
|
|
|
crossAttrs = {
|
|
configureFlags = configureFlagsFun { alsaLib = alsaLib.crossDrv; };
|
|
};
|
|
|
|
postInstall = ''
|
|
moveToOutput lib/libSDL2main.a "$dev"
|
|
rm $out/lib/*.a
|
|
moveToOutput bin/sdl2-config "$dev"
|
|
'';
|
|
|
|
setupHook = ./setup-hook.sh;
|
|
|
|
passthru = { inherit openglSupport; };
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "A cross-platform multimedia library";
|
|
homepage = http://www.libsdl.org/;
|
|
license = licenses.zlib;
|
|
platforms = platforms.all;
|
|
maintainers = with maintainers; [ cpages ];
|
|
};
|
|
}
|