mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-23 07:26:54 +00:00
76 lines
2.9 KiB
Nix
76 lines
2.9 KiB
Nix
{ stdenv, fetchFromGitHub, fetchpatch, lib
|
|
, autoconf, automake, gnum4, libtool, perl, gnulib, uthash, pkgconfig, gettext
|
|
, python, freetype, zlib, glib, libungif, libpng, libjpeg, libtiff, libxml2, pango
|
|
, withSpiro ? false, libspiro
|
|
, withGTK ? false, gtk2
|
|
, withPython ? true
|
|
, Carbon ? null, Cocoa ? null
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "fontforge-${version}";
|
|
version = "20170730";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "fontforge";
|
|
repo = "fontforge";
|
|
rev = version;
|
|
sha256 = "15k6x97383p8l40jvcivalhwgbbcdg5vciyjz6m9r0lrlnjqkv99";
|
|
};
|
|
|
|
patches = [ ./fontforge-20140813-use-system-uthash.patch ];
|
|
|
|
# use $SOURCE_DATE_EPOCH instead of non-determenistic timestamps
|
|
postPatch = ''
|
|
find . -type f -name '*.c' -exec sed -r -i 's#\btime\(&(.+)\)#if (getenv("SOURCE_DATE_EPOCH")) \1=atol(getenv("SOURCE_DATE_EPOCH")); else &#g' {} \;
|
|
sed -r -i 's#author\s*!=\s*NULL#& \&\& !getenv("SOURCE_DATE_EPOCH")#g' fontforge/cvexport.c fontforge/dumppfa.c fontforge/print.c fontforge/svg.c fontforge/splineutil2.c
|
|
sed -r -i 's#\bb.st_mtime#getenv("SOURCE_DATE_EPOCH") ? atol(getenv("SOURCE_DATE_EPOCH")) : &#g' fontforge/parsepfa.c fontforge/sfd.c fontforge/svg.c
|
|
sed -r -i 's#^\s*ttf_fftm_dump#if (!getenv("SOURCE_DATE_EPOCH")) ttf_fftm_dump#g' fontforge/tottf.c
|
|
sed -r -i 's#sprintf\(.+ author \);#if (!getenv("SOURCE_DATE_EPOCH")) &#g' fontforgeexe/fontinfo.c
|
|
'';
|
|
|
|
# do not use x87's 80-bit arithmetic, rouding errors result in very different font binaries
|
|
NIX_CFLAGS_COMPILE = lib.optionals stdenv.isi686 [ "-msse2" "-mfpmath=sse" ];
|
|
|
|
nativeBuildInputs = [ pkgconfig ];
|
|
buildInputs = [
|
|
autoconf automake gnum4 libtool perl gettext uthash
|
|
python freetype zlib glib libungif libpng libjpeg libtiff libxml2
|
|
]
|
|
++ lib.optionals withSpiro [libspiro]
|
|
++ lib.optionals withGTK [ gtk2 pango ]
|
|
++ lib.optionals stdenv.isDarwin [ Carbon Cocoa ];
|
|
|
|
configureFlags =
|
|
lib.optionals (!withPython) [ "--disable-python-scripting" "--disable-python-extension" ]
|
|
++ lib.optional withGTK "--enable-gtk2-use"
|
|
++ lib.optional (!withGTK) "--without-x";
|
|
|
|
# work-around: git isn't really used, but configuration fails without it
|
|
preConfigure = ''
|
|
# The way $version propagates to $version of .pe-scripts (https://github.com/dejavu-fonts/dejavu-fonts/blob/358190f/scripts/generate.pe#L19)
|
|
export SOURCE_DATE_EPOCH=$(date -d ${version} +%s)
|
|
|
|
export GIT="$(type -P true)"
|
|
cp -r "${gnulib}" ./gnulib
|
|
chmod +w -R ./gnulib
|
|
./bootstrap --skip-git --gnulib-srcdir=./gnulib
|
|
'';
|
|
|
|
postInstall =
|
|
# get rid of the runtime dependency on python
|
|
lib.optionalString (!withPython) ''
|
|
rm -r "$out/share/fontforge/python"
|
|
'';
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
meta = {
|
|
description = "A font editor";
|
|
homepage = http://fontforge.github.io;
|
|
platforms = stdenv.lib.platforms.all;
|
|
license = stdenv.lib.licenses.bsd3;
|
|
};
|
|
}
|
|
|