mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-24 22:50:49 +00:00
bd5324c4fc
Upgrades Hydra to the latest master/flake branch. To perform this upgrade, it's needed to do a non-trivial db-migration which provides a massive performance-improvement[1]. The basic ideas behind multi-step upgrades of services between NixOS versions have been gathered already[2]. For further context it's recommended to read this first. Basically, the following steps are needed: * Upgrade to a non-breaking version of Hydra with the db-changes (columns are still nullable here). If `system.stateVersion` is set to something older than 20.03, the package will be selected automatically, otherwise `pkgs.hydra-migration` needs to be used. * Run `hydra-backfill-ids` on the server. * Deploy either `pkgs.hydra-unstable` (for Hydra master) or `pkgs.hydra-flakes` (for flakes-support) to activate the optimization. The steps are also documented in the release-notes and in the module using `warnings`. `pkgs.hydra` has been removed as latest Hydra doesn't compile with `pkgs.nixStable` and to ensure a graceful migration using the newly introduced packages. To verify the approach, a simple vm-test has been added which verifies the migration steps. [1] https://github.com/NixOS/hydra/pull/711 [2] https://github.com/NixOS/nixpkgs/pull/82353#issuecomment-598269471
60 lines
1.7 KiB
Nix
60 lines
1.7 KiB
Nix
{ system ? builtins.currentSystem
|
|
, config ? { }
|
|
, pkgs ? import ../../.. { inherit system config; }
|
|
}:
|
|
|
|
with import ../../lib/testing-python.nix { inherit system pkgs; };
|
|
with pkgs.lib;
|
|
|
|
let
|
|
|
|
inherit (import ./common.nix { inherit system; }) baseConfig;
|
|
|
|
hydraPkgs = {
|
|
inherit (pkgs) hydra-migration hydra-unstable hydra-flakes;
|
|
};
|
|
|
|
makeHydraTest = with pkgs.lib; name: package: makeTest {
|
|
name = "hydra-${name}";
|
|
meta = with pkgs.stdenv.lib.maintainers; {
|
|
maintainers = [ pstn lewo ma27 ];
|
|
};
|
|
|
|
machine = { pkgs, lib, ... }: {
|
|
imports = [ baseConfig ];
|
|
services.hydra = { inherit package; };
|
|
};
|
|
|
|
testScript = ''
|
|
# let the system boot up
|
|
machine.wait_for_unit("multi-user.target")
|
|
# test whether the database is running
|
|
machine.wait_for_unit("postgresql.service")
|
|
# test whether the actual hydra daemons are running
|
|
machine.wait_for_unit("hydra-init.service")
|
|
machine.require_unit_state("hydra-queue-runner.service")
|
|
machine.require_unit_state("hydra-evaluator.service")
|
|
machine.require_unit_state("hydra-notify.service")
|
|
|
|
machine.succeed("hydra-create-user admin --role admin --password admin")
|
|
|
|
# create a project with a trivial job
|
|
machine.wait_for_open_port(3000)
|
|
|
|
# make sure the build as been successfully built
|
|
machine.succeed("create-trivial-project.sh")
|
|
|
|
machine.wait_until_succeeds(
|
|
'curl -L -s http://localhost:3000/build/1 -H "Accept: application/json" | jq .buildstatus | xargs test 0 -eq'
|
|
)
|
|
|
|
machine.wait_until_succeeds(
|
|
'journalctl -eu hydra-notify.service -o cat | grep -q "sending mail notification to hydra@localhost"'
|
|
)
|
|
'';
|
|
};
|
|
|
|
in
|
|
|
|
mapAttrs makeHydraTest hydraPkgs
|