mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-25 03:17:13 +00:00
d8dde72fbb
1. Launching an app externally (like we do in tests) does not dismiss the GNOME Shell’s Activities view opened on log-in.
2. Activities view grabs input so that user can type to search.
3. Due to a regression in Mutter 44, a window focus is not acquired when Shell grabs input
3ac82a58c5
As a result, trying to determine the WMClass would throw:
TypeError: global.display.focus_window is null
Let’s dismiss the Activities view with Escape key as a workaround.
100 lines
3.3 KiB
Nix
100 lines
3.3 KiB
Nix
import ./make-test-python.nix ({ pkgs, lib, ...} : {
|
|
name = "gnome-xorg";
|
|
meta = with lib; {
|
|
maintainers = teams.gnome.members;
|
|
};
|
|
|
|
nodes.machine = { nodes, ... }: let
|
|
user = nodes.machine.config.users.users.alice;
|
|
in
|
|
|
|
{ imports = [ ./common/user-account.nix ];
|
|
|
|
services.xserver.enable = true;
|
|
|
|
services.xserver.displayManager = {
|
|
gdm.enable = true;
|
|
gdm.debug = true;
|
|
autoLogin = {
|
|
enable = true;
|
|
user = user.name;
|
|
};
|
|
};
|
|
|
|
services.xserver.desktopManager.gnome.enable = true;
|
|
services.xserver.desktopManager.gnome.debug = true;
|
|
services.xserver.displayManager.defaultSession = "gnome-xorg";
|
|
|
|
systemd.user.services = {
|
|
"org.gnome.Shell@x11" = {
|
|
serviceConfig = {
|
|
ExecStart = [
|
|
# Clear the list before overriding it.
|
|
""
|
|
# Eval API is now internal so Shell needs to run in unsafe mode.
|
|
# TODO: improve test driver so that it supports openqa-like manipulation
|
|
# that would allow us to drop this mess.
|
|
"${pkgs.gnome.gnome-shell}/bin/gnome-shell --unsafe-mode"
|
|
];
|
|
};
|
|
};
|
|
};
|
|
|
|
};
|
|
|
|
testScript = { nodes, ... }: let
|
|
user = nodes.machine.config.users.users.alice;
|
|
uid = toString user.uid;
|
|
bus = "DBUS_SESSION_BUS_ADDRESS=unix:path=/run/user/${uid}/bus";
|
|
xauthority = "/run/user/${uid}/gdm/Xauthority";
|
|
display = "DISPLAY=:0.0";
|
|
env = "${bus} XAUTHORITY=${xauthority} ${display}";
|
|
gdbus = "${env} gdbus";
|
|
su = command: "su - ${user.name} -c '${env} ${command}'";
|
|
|
|
# Call javascript in gnome shell, returns a tuple (success, output), where
|
|
# `success` is true if the dbus call was successful and output is what the
|
|
# javascript evaluates to.
|
|
eval = "call --session -d org.gnome.Shell -o /org/gnome/Shell -m org.gnome.Shell.Eval";
|
|
|
|
# False when startup is done
|
|
startingUp = su "${gdbus} ${eval} Main.layoutManager._startingUp";
|
|
|
|
# Start Console
|
|
launchConsole = su "${bus} gapplication launch org.gnome.Console";
|
|
|
|
# Hopefully Console's wm class
|
|
wmClass = su "${gdbus} ${eval} global.display.focus_window.wm_class";
|
|
in ''
|
|
with subtest("Login to GNOME Xorg with GDM"):
|
|
machine.wait_for_x()
|
|
# Wait for alice to be logged in"
|
|
machine.wait_for_unit("default.target", "${user.name}")
|
|
machine.wait_for_file("${xauthority}")
|
|
machine.succeed("xauth merge ${xauthority}")
|
|
# Check that logging in has given the user ownership of devices
|
|
assert "alice" in machine.succeed("getfacl -p /dev/snd/timer")
|
|
|
|
with subtest("Wait for GNOME Shell"):
|
|
# correct output should be (true, 'false')
|
|
machine.wait_until_succeeds(
|
|
"${startingUp} | grep -q 'true,..false'"
|
|
)
|
|
|
|
with subtest("Open Console"):
|
|
# Close the Activities view so that Shell can correctly track the focused window.
|
|
machine.send_key("esc")
|
|
|
|
machine.succeed(
|
|
"${launchConsole}"
|
|
)
|
|
# correct output should be (true, '"kgx"')
|
|
# For some reason, this deviates from Wayland.
|
|
machine.wait_until_succeeds(
|
|
"${wmClass} | grep -q 'true,...kgx'"
|
|
)
|
|
machine.sleep(20)
|
|
machine.screenshot("screen")
|
|
'';
|
|
})
|