mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-25 03:17:13 +00:00
1e95e114e5
While systemd suggests using the pre-defined graphical-session user target, I found that this interface is difficult to use. Additionally, no other major distribution, even in their unstable versions, currently use this mechanism. The window or desktop manager is supposed to run in a systemd user service which activates graphical-session.target and the user services that are binding to this target. The issue is that we can't elegantly pass the xsession environment to the window manager session, in particular whereas the PassEnvironment option does work for DISPLAY, it for some mysterious reason won't for PATH. This commit implements a new graphical user target that works just like default.target. Services which should be run in a graphical session just need to declare wantedBy graphical.target. The graphical target will be activated in the xsession before executing the window or display manager. Fixes #17858.
59 lines
1.6 KiB
Nix
59 lines
1.6 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let cfg = config.services.unclutter-xfixes;
|
|
|
|
in {
|
|
options.services.unclutter-xfixes = {
|
|
|
|
enable = mkOption {
|
|
description = "Enable unclutter-xfixes to hide your mouse cursor when inactive.";
|
|
type = types.bool;
|
|
default = false;
|
|
};
|
|
|
|
package = mkOption {
|
|
description = "unclutter-xfixes derivation to use.";
|
|
type = types.package;
|
|
default = pkgs.unclutter-xfixes;
|
|
defaultText = "pkgs.unclutter-xfixes";
|
|
};
|
|
|
|
timeout = mkOption {
|
|
description = "Number of seconds before the cursor is marked inactive.";
|
|
type = types.int;
|
|
default = 1;
|
|
};
|
|
|
|
threshold = mkOption {
|
|
description = "Minimum number of pixels considered cursor movement.";
|
|
type = types.int;
|
|
default = 1;
|
|
};
|
|
|
|
extraOptions = mkOption {
|
|
description = "More arguments to pass to the unclutter-xfixes command.";
|
|
type = types.listOf types.str;
|
|
default = [];
|
|
example = [ "exclude-root" "ignore-scrolling" "fork" ];
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
systemd.user.services.unclutter-xfixes = {
|
|
description = "unclutter-xfixes";
|
|
wantedBy = [ "graphical-session.target" ];
|
|
partOf = [ "graphical-session.target" ];
|
|
serviceConfig.ExecStart = ''
|
|
${cfg.package}/bin/unclutter \
|
|
--timeout ${toString cfg.timeout} \
|
|
--jitter ${toString (cfg.threshold - 1)} \
|
|
${concatMapStrings (x: " --"+x) cfg.extraOptions} \
|
|
'';
|
|
serviceConfig.RestartSec = 3;
|
|
serviceConfig.Restart = "always";
|
|
};
|
|
};
|
|
}
|