mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-01 01:51:24 +00:00
c7bac81c66
Both branches have quite a lot in common, so it's time for a merge and do the cleanups with respect to both implementations and also generalize both implementations as much as possible. This also closes #1876. Conflicts: pkgs/development/interpreters/lua-5/5.2.nix pkgs/development/libraries/SDL/default.nix pkgs/development/libraries/glew/default.nix pkgs/top-level/all-packages.nix
51 lines
1.3 KiB
Nix
51 lines
1.3 KiB
Nix
{ stdenv, fetchurl, mesa_glu, x11, libXmu, libXi }:
|
|
|
|
with stdenv.lib;
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "glew-1.10.0";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://sourceforge/glew/${name}.tgz";
|
|
sha256 = "01zki46dr5khzlyywr3cg615bcal32dazfazkf360s1znqh17i4r";
|
|
};
|
|
|
|
nativeBuildInputs = [ x11 libXmu libXi ];
|
|
propagatedNativeBuildInputs = [ mesa_glu ]; # GL/glew.h includes GL/glu.h
|
|
|
|
patchPhase = ''
|
|
sed -i 's|lib64|lib|' config/Makefile.linux
|
|
${optionalString (stdenv ? cross) ''
|
|
sed -i -e 's/\(INSTALL.*\)-s/\1/' Makefile
|
|
''}
|
|
'';
|
|
|
|
buildFlags = [ "all" ];
|
|
installFlags = [ "install.all" ];
|
|
|
|
preInstall = ''
|
|
export GLEW_DEST="$out"
|
|
'';
|
|
|
|
postInstall = ''
|
|
mkdir -pv $out/share/doc/glew
|
|
mkdir -p $out/lib/pkgconfig
|
|
cp glew*.pc $out/lib/pkgconfig
|
|
cp -r README.txt LICENSE.txt doc $out/share/doc/glew
|
|
'';
|
|
|
|
crossAttrs.makeFlags = [
|
|
"CC=${stdenv.cross.config}-gcc"
|
|
"LD=${stdenv.cross.config}-gcc"
|
|
"AR=${stdenv.cross.config}-ar"
|
|
"STRIP="
|
|
] ++ optional (stdenv.cross.libc == "msvcrt") "SYSTEM=mingw"
|
|
++ optional (stdenv.cross.libc == "libSystem") "SYSTEM=darwin";
|
|
|
|
meta = {
|
|
description = "An OpenGL extension loading library for C(++)";
|
|
homepage = http://glew.sourceforge.net/;
|
|
license = ["BSD" "GLX" "SGI-B" "GPL2"]; # License description copied from gentoo-1.4.0
|
|
};
|
|
}
|