mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-25 23:20:55 +00:00
018a5ae2f4
Fetch into $out and remove all version control files to make it deterministic (.repo and all .git subdirectories - e.g. the .git/index files change every time). Additionally I've changed the default of "useArchive" to false because fetching with "--archive" will fail for some projects (e.g. "platform/external/iosched" from the AOSP). Now, this function should hopefully work for every tag of the AOSP.
78 lines
2.2 KiB
Nix
78 lines
2.2 KiB
Nix
{ stdenv, gitRepo, cacert, copyPathsToStore }:
|
|
|
|
{ name, manifest, rev ? "HEAD", sha256
|
|
# Optional parameters:
|
|
, repoRepoURL ? "", repoRepoRev ? "", referenceDir ? ""
|
|
, localManifests ? [], createMirror ? false, useArchive ? false
|
|
}:
|
|
|
|
assert repoRepoRev != "" -> repoRepoURL != "";
|
|
assert createMirror -> !useArchive;
|
|
|
|
with stdenv.lib;
|
|
|
|
let
|
|
extraRepoInitFlags = [
|
|
(optionalString (repoRepoURL != "") "--repo-url=${repoRepoURL}")
|
|
(optionalString (repoRepoRev != "") "--repo-branch=${repoRepoRev}")
|
|
(optionalString (referenceDir != "") "--reference=${referenceDir}")
|
|
];
|
|
|
|
repoInitFlags = [
|
|
"--manifest-url=${manifest}"
|
|
"--manifest-branch=${rev}"
|
|
"--depth=1"
|
|
(optionalString createMirror "--mirror")
|
|
(optionalString useArchive "--archive")
|
|
] ++ extraRepoInitFlags;
|
|
|
|
local_manifests = copyPathsToStore localManifests;
|
|
|
|
in stdenv.mkDerivation {
|
|
inherit name;
|
|
|
|
inherit cacert manifest rev repoRepoURL repoRepoRev referenceDir; # TODO
|
|
|
|
outputHashAlgo = "sha256";
|
|
outputHashMode = "recursive";
|
|
outputHash = sha256;
|
|
|
|
preferLocalBuild = true;
|
|
enableParallelBuilding = true;
|
|
|
|
impureEnvVars = fetchers.proxyImpureEnvVars ++ [
|
|
"GIT_PROXY_COMMAND" "SOCKS_SERVER"
|
|
];
|
|
|
|
buildInputs = [ gitRepo cacert ];
|
|
|
|
GIT_SSL_CAINFO = "${cacert}/etc/ssl/certs/ca-bundle.crt";
|
|
|
|
buildCommand = ''
|
|
# Path must be absolute (e.g. for GnuPG: ~/.repoconfig/gnupg/pubring.kbx)
|
|
export HOME="$(pwd)"
|
|
|
|
mkdir $out
|
|
cd $out
|
|
|
|
mkdir .repo
|
|
${optionalString (local_manifests != []) ''
|
|
mkdir .repo/local_manifests
|
|
for local_manifest in ${concatMapStringsSep " " toString local_manifests}; do
|
|
cp $local_manifest .repo/local_manifests/$(stripHash $local_manifest; echo $strippedName)
|
|
done
|
|
''}
|
|
|
|
repo init ${concatStringsSep " " repoInitFlags}
|
|
repo sync --jobs=$NIX_BUILD_CORES --current-branch
|
|
|
|
# TODO: The git-index files (and probably the files in .repo as well) have
|
|
# different contents each time and will therefore change the final hash
|
|
# (i.e. creating a mirror probably won't work).
|
|
${optionalString (!createMirror) ''
|
|
rm -rf .repo
|
|
find -type d -name '.git' -prune -exec rm -rf {} +
|
|
''}
|
|
'';
|
|
}
|