mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-20 12:42:24 +00:00
74e7ef35fe
This allows you to specify the system-wide flake registry. One use is
to pin 'nixpkgs' to the Nixpkgs version used to build the system:
nix.registry.nixpkgs.flake = nixpkgs;
where 'nixpkgs' is a flake input. This ensures that commands like
$ nix run nixpkgs#hello
pull in a minimum of additional store paths.
You can also use this to redirect flakes, e.g.
nix.registry.nixpkgs.to = {
type = "github";
owner = "my-org";
repo = "my-nixpkgs";
};
52 lines
1.4 KiB
Nix
52 lines
1.4 KiB
Nix
# Experimental flake interface to Nixpkgs.
|
|
# See https://github.com/NixOS/rfcs/pull/49 for details.
|
|
{
|
|
edition = 201909;
|
|
|
|
description = "A collection of packages for the Nix package manager";
|
|
|
|
outputs = { self }:
|
|
let
|
|
|
|
jobs = import ./pkgs/top-level/release.nix {
|
|
nixpkgs = self;
|
|
};
|
|
|
|
lib = import ./lib;
|
|
|
|
systems = [ "x86_64-linux" "i686-linux" "x86_64-darwin" "aarch64-linux" ];
|
|
|
|
forAllSystems = f: lib.genAttrs systems (system: f system);
|
|
|
|
in
|
|
{
|
|
lib = lib // {
|
|
nixosSystem = { modules, ... } @ args:
|
|
import ./nixos/lib/eval-config.nix (args // {
|
|
modules = modules ++
|
|
[ { system.nixos.versionSuffix =
|
|
".${lib.substring 0 8 (self.lastModifiedDate or self.lastModified)}.${self.shortRev or "dirty"}";
|
|
system.nixos.revision = lib.mkIf (self ? rev) self.rev;
|
|
nix.registry.nixpkgs.flake = lib.mkDefault self;
|
|
}
|
|
];
|
|
});
|
|
};
|
|
|
|
checks.x86_64-linux.tarball = jobs.tarball;
|
|
|
|
htmlDocs = {
|
|
nixpkgsManual = jobs.manual;
|
|
nixosManual = (import ./nixos/release-small.nix {
|
|
nixpkgs = self;
|
|
}).nixos.manual.x86_64-linux;
|
|
};
|
|
|
|
legacyPackages = forAllSystems (system: import ./. { inherit system; });
|
|
|
|
nixosModules = {
|
|
notDetected = import ./nixos/modules/installer/scan/not-detected.nix;
|
|
};
|
|
};
|
|
}
|