mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-24 02:46:38 +00:00
47 lines
1.3 KiB
Nix
47 lines
1.3 KiB
Nix
{ lib, buildGoModule, fetchFromGitHub, makeWrapper, iptables, iproute2 }:
|
|
|
|
buildGoModule rec {
|
|
pname = "tailscale";
|
|
version = "1.10.2";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "tailscale";
|
|
repo = "tailscale";
|
|
rev = "v${version}";
|
|
sha256 = "sha256-bAWQTdpqDF7ERQzNY1k0NtxdA9M9bIyfHtvX0nKfIQY=";
|
|
};
|
|
|
|
nativeBuildInputs = [ makeWrapper ];
|
|
|
|
CGO_ENABLED = 0;
|
|
|
|
vendorSha256 = "1mq5bbz9vsxhcrwxpsdnhp8q8zrnp6jpqggn9n5kqr82f3bizwxv";
|
|
|
|
doCheck = false;
|
|
|
|
subPackages = [ "cmd/tailscale" "cmd/tailscaled" ];
|
|
|
|
preBuild = ''
|
|
export buildFlagsArray=(
|
|
-tags="xversion"
|
|
-ldflags="-X tailscale.com/version.Long=${version} -X tailscale.com/version.Short=${version}"
|
|
)
|
|
'';
|
|
|
|
postInstall = ''
|
|
wrapProgram $out/bin/tailscaled --prefix PATH : ${
|
|
lib.makeBinPath [ iproute2 iptables ]
|
|
}
|
|
sed -i -e "s#/usr/sbin#$out/bin#" -e "/^EnvironmentFile/d" ./cmd/tailscaled/tailscaled.service
|
|
install -D -m0444 -t $out/lib/systemd/system ./cmd/tailscaled/tailscaled.service
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://tailscale.com";
|
|
description = "The node agent for Tailscale, a mesh VPN built on WireGuard";
|
|
platforms = platforms.linux;
|
|
license = licenses.bsd3;
|
|
maintainers = with maintainers; [ danderson mbaillie ];
|
|
};
|
|
}
|