mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-18 03:30:45 +00:00
755b915a15
nix run nixpkgs#silver-searcher -- -G '\.nix$' -0l 'description.*"[Aa]n?' pkgs \ | xargs -0 nix run nixpkgs#gnused -- -i '' -Ee 's/(description.*")[Aa]n? (.)/\1\U\2/'
48 lines
1.3 KiB
Nix
48 lines
1.3 KiB
Nix
{ lib, stdenv, fetchurl, dpkg, jdk11, nixosTests }:
|
|
|
|
let
|
|
pname = "jigasi";
|
|
version = "1.1-311-g3de47d0";
|
|
src = fetchurl {
|
|
url = "https://download.jitsi.org/stable/${pname}_${version}-1_all.deb";
|
|
hash = "sha256-pwUgkId7AHFjbqYo02fBgm0gsiMqEz+wvwkdy6sgTD0=";
|
|
};
|
|
in
|
|
stdenv.mkDerivation {
|
|
inherit pname version src;
|
|
|
|
nativeBuildInputs = [ dpkg ];
|
|
|
|
dontBuild = true;
|
|
|
|
unpackCmd = "dpkg-deb -x $src debcontents";
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
substituteInPlace usr/share/${pname}/${pname}.sh \
|
|
--replace "exec java" "exec ${jdk11}/bin/java"
|
|
|
|
mkdir -p $out/{share,bin}
|
|
mv usr/share/${pname} $out/share/
|
|
mv etc $out/
|
|
ln -s $out/share/${pname}/${pname}.sh $out/bin/${pname}
|
|
runHook postInstall
|
|
'';
|
|
|
|
passthru.tests = {
|
|
single-node-smoke-test = nixosTests.jitsi-meet;
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Server-side application that allows regular SIP clients to join Jitsi Meet conferences";
|
|
mainProgram = "jigasi";
|
|
longDescription = ''
|
|
Jitsi Gateway to SIP: a server-side application that allows regular SIP clients to join Jitsi Meet conferences hosted by Jitsi Videobridge.
|
|
'';
|
|
homepage = "https://github.com/jitsi/jigasi";
|
|
license = licenses.asl20;
|
|
maintainers = teams.jitsi.members;
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|