mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-25 03:17:13 +00:00
9bb3fccb5b
continuation of #109595 pkgconfig was aliased in 2018, however, it remained in all-packages.nix due to its wide usage. This cleans up the remaining references to pkgs.pkgsconfig and moves the entry to aliases.nix. python3Packages.pkgconfig remained unchanged because it's the canonical name of the upstream package on pypi.
53 lines
1.4 KiB
Nix
53 lines
1.4 KiB
Nix
{ stdenv, fetchurl, lib, file
|
|
, pkg-config
|
|
, gtkVersion ? "3", gtk2 ? null, gtk3 ? null }:
|
|
|
|
with lib;
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "libindicator-gtk${gtkVersion}-${version}";
|
|
version = "${versionMajor}.${versionMinor}";
|
|
versionMajor = "12.10";
|
|
versionMinor = "1";
|
|
|
|
src = fetchurl {
|
|
url = "${meta.homepage}/${versionMajor}/${version}/+download/libindicator-${version}.tar.gz";
|
|
sha256 = "b2d2e44c10313d5c9cd60db455d520f80b36dc39562df079a3f29495e8f9447f";
|
|
};
|
|
|
|
nativeBuildInputs = [ pkg-config ];
|
|
|
|
buildInputs = [ (if gtkVersion == "2" then gtk2 else gtk3) ];
|
|
|
|
postPatch = ''
|
|
substituteInPlace configure \
|
|
--replace 'LIBINDICATOR_LIBS+="$LIBM"' 'LIBINDICATOR_LIBS+=" $LIBM"'
|
|
for f in {build-aux/ltmain.sh,configure,m4/libtool.m4}; do
|
|
substituteInPlace $f\
|
|
--replace /usr/bin/file ${file}/bin/file
|
|
done
|
|
'';
|
|
|
|
configureFlags = [
|
|
"CFLAGS=-Wno-error"
|
|
"--sysconfdir=/etc"
|
|
"--localstatedir=/var"
|
|
"--with-gtk=${gtkVersion}"
|
|
];
|
|
|
|
installFlags = [
|
|
"sysconfdir=\${out}/etc"
|
|
"localstatedir=\${TMPDIR}"
|
|
];
|
|
|
|
doCheck = false; # fails 8 out of 8 tests
|
|
|
|
meta = {
|
|
description = "A set of symbols and convenience functions for Ayatana indicators";
|
|
homepage = "https://launchpad.net/libindicator";
|
|
license = licenses.gpl3;
|
|
platforms = platforms.linux;
|
|
maintainers = [ maintainers.msteen ];
|
|
};
|
|
}
|