mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-28 08:31:59 +00:00
274715cbc3
luaPackages replaced by generated ones:
- bit32
- compat53
- cqueues
- luacyrussasl -> cyrussasl (luarocks name)
- luaexpat
- luadbi -> luadbi front-end module + separate backend modules
luadbi-{mysql,postgresql,sqlite3}
- luafilesystem
- luaossl
- luasec
- luasocket
- luastdlib -> stdlib (luarocks name)
- lrexlib -> lrexlib-pcre (we already have lrexlib-gnu and
lrexlib-posix, lrexlib-pcre however appears to be the variant used in
mudlet, which is the only current dep in nixpkgs)
- luasqlite -> luasql-sqlite3 (luarocks name)
- lfs -> luafilesytem (we literally had two manually written
luafilesystem expressions, under different names)
Changes and additions to overrides to generated luarocks packgaes,
including:
- busted: Install bash completions along with the zsh ones
- cqueues:
- Perform minor surgery on the rockspec to allow using a single
rockspec to build for all supported Lua versions
- Add a patch by @vcunat to work around a build issue
- luuid: Wrote a tiny patch to allow for Lua 5.1/Luajit compatibility
- General changes:
- Sorted the packages
- Attempted to make the formatting consistent
- Preferenced `.override` instead of `.overrideAttrs` wherever
possible
Minor changes to other packages to adjust for the Lua package changes:
- luakit expression simplified
- prosody expression simplified; but users will now need to specify the
luadbi backend module they intend to use in withExtraLibs
- knot-resolver inputs correctd
- mudlet inputs corrected (although this package was and should still be
broken)
75 lines
2.2 KiB
Nix
75 lines
2.2 KiB
Nix
{ stdenv, fetchurl, libidn, openssl, makeWrapper, fetchhg
|
|
, lua5, luasocket, luasec, luaexpat, luafilesystem, luabitop
|
|
, withLibevent ? true, luaevent ? null
|
|
, withDBI ? true, luadbi ? null
|
|
# use withExtraLibs to add additional dependencies of community modules
|
|
, withExtraLibs ? [ ]
|
|
, withOnlyInstalledCommunityModules ? [ ]
|
|
, withCommunityModules ? [ ] }:
|
|
|
|
assert withLibevent -> luaevent != null;
|
|
assert withDBI -> luadbi != null;
|
|
|
|
with stdenv.lib;
|
|
|
|
|
|
stdenv.mkDerivation rec {
|
|
version = "0.11.2"; # also update communityModules
|
|
name = "prosody-${version}";
|
|
|
|
src = fetchurl {
|
|
url = "https://prosody.im/downloads/source/${name}.tar.gz";
|
|
sha256 = "0ca8ivqb4hxqka08pwnaqi1bqxrdl8zw47g6z7nw9q5r57fgc4c9";
|
|
};
|
|
|
|
# A note to all those merging automated updates: Please also update this
|
|
# attribute as some modules might not be compatible with a newer prosody
|
|
# version.
|
|
communityModules = fetchhg {
|
|
url = "https://hg.prosody.im/prosody-modules";
|
|
rev = "b54e98d5c4a1";
|
|
sha256 = "0bzn92j48krb2zhp9gn5bbn5sg0qv15j5lpxfszwqdln3lpmrvzg";
|
|
};
|
|
|
|
buildInputs = [
|
|
lua5 makeWrapper libidn openssl
|
|
]
|
|
# Lua libraries
|
|
++ [
|
|
luasocket luasec luaexpat luafilesystem luabitop
|
|
]
|
|
++ optional withLibevent luaevent
|
|
++ optional withDBI luadbi
|
|
++ withExtraLibs;
|
|
|
|
|
|
configureFlags = [
|
|
"--ostype=linux"
|
|
"--with-lua-include=${lua5}/include"
|
|
"--with-lua=${lua5}"
|
|
];
|
|
|
|
postInstall = ''
|
|
${concatMapStringsSep "\n" (module: ''
|
|
cp -r $communityModules/mod_${module} $out/lib/prosody/modules/
|
|
'') (withCommunityModules ++ withOnlyInstalledCommunityModules)}
|
|
wrapProgram $out/bin/prosody \
|
|
--prefix LUA_PATH ';' "$NIX_LUA_PATH" \
|
|
--prefix LUA_CPATH ';' "$NIX_LUA_CPATH"
|
|
wrapProgram $out/bin/prosodyctl \
|
|
--add-flags '--config "/etc/prosody/prosody.cfg.lua"' \
|
|
--prefix LUA_PATH ';' "$NIX_LUA_PATH" \
|
|
--prefix LUA_CPATH ';' "$NIX_LUA_CPATH"
|
|
'';
|
|
|
|
passthru.communityModules = withCommunityModules;
|
|
|
|
meta = {
|
|
description = "Open-source XMPP application server written in Lua";
|
|
license = licenses.mit;
|
|
homepage = https://prosody.im;
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ fpletz globin ];
|
|
};
|
|
}
|