mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-04 19:45:54 +00:00
42a3276e9a
* flyway: 5.2.1 -> 5.2.4 (#52325) Semi-automatic update generated by https://github.com/ryantm/nixpkgs-update tools. This update was made based on information from https://repology.org/metapackage/flyway/versions * flyway: makeWrapper is a build-time input moved it from buildInputs to nativeBuildInputs
31 lines
1.2 KiB
Nix
31 lines
1.2 KiB
Nix
{ stdenv, fetchurl, jre_headless, makeWrapper }:
|
|
let
|
|
version = "5.2.4";
|
|
in
|
|
stdenv.mkDerivation {
|
|
name = "flyway-${version}";
|
|
src = fetchurl {
|
|
url = "https://repo1.maven.org/maven2/org/flywaydb/flyway-commandline/${version}/flyway-commandline-${version}.tar.gz";
|
|
sha256 = "16ia6nlvj4cgmdkn66bjg73h5vah82hpzk9mf0n5kmqnwcaa8hmc";
|
|
};
|
|
nativeBuildInputs = [ makeWrapper ];
|
|
dontBuild = true;
|
|
dontStrip = true;
|
|
installPhase = ''
|
|
mkdir -p $out/bin $out/share/flyway
|
|
cp -r sql jars drivers conf $out/share/flyway
|
|
cp -r lib/community $out/share/flyway/lib
|
|
makeWrapper "${jre_headless}/bin/java" $out/bin/flyway \
|
|
--add-flags "-Djava.security.egd=file:/dev/../dev/urandom" \
|
|
--add-flags "-classpath '$out/share/flyway/lib/*:$out/share/flyway/drivers/*'" \
|
|
--add-flags "org.flywaydb.commandline.Main"
|
|
'';
|
|
meta = with stdenv.lib; {
|
|
description = "Evolve your Database Schema easily and reliably across all your instances";
|
|
homepage = "https://flywaydb.org/";
|
|
license = licenses.asl20;
|
|
platforms = platforms.unix;
|
|
maintainers = [ maintainers.cmcdragonkai ];
|
|
};
|
|
}
|