mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-26 07:31:20 +00:00
2034c06a0a
Reverse bootstrapping is not supported by GHC upstream. In the case of 8.8.4 it just happens to work using 8.10.2, with later versions, specifically 8.10.7 there seems to be some digressions in the generated / used C code which cause 8.8.4 to fail to compile [1]. Thus we revert to using 8.10.2 for aarch64 and Musl which means: Still no integer-simple and musl at the same time (however all other GHCs have it, so it's probably not a problem) and no aarch64-darwin (GHC 8.8.4 can't target that architecture anyways). In short, the situation stays the same. [1]: https://github.com/NixOS/nixpkgs/pull/138523#issuecomment-927339953
267 lines
10 KiB
Nix
267 lines
10 KiB
Nix
{ buildPackages, pkgs, newScope, stdenv }:
|
|
|
|
let
|
|
# These are attributes in compiler and packages that don't support integer-simple.
|
|
integerSimpleExcludes = [
|
|
"ghc865Binary"
|
|
"ghc8102Binary"
|
|
"ghc8102BinaryMinimal"
|
|
"ghc8107Binary"
|
|
"ghc8107BinaryMinimal"
|
|
"ghcjs"
|
|
"ghcjs810"
|
|
"integer-simple"
|
|
"native-bignum"
|
|
"ghcHEAD"
|
|
];
|
|
|
|
nativeBignumIncludes = [
|
|
"ghcHEAD"
|
|
];
|
|
|
|
haskellLib = import ../development/haskell-modules/lib.nix {
|
|
inherit (pkgs) lib;
|
|
inherit pkgs;
|
|
};
|
|
|
|
callPackage = newScope {
|
|
inherit haskellLib;
|
|
overrides = pkgs.haskell.packageOverrides;
|
|
};
|
|
|
|
bootstrapPackageSet = self: super: {
|
|
mkDerivation = drv: super.mkDerivation (drv // {
|
|
doCheck = false;
|
|
doHaddock = false;
|
|
enableExecutableProfiling = false;
|
|
enableLibraryProfiling = false;
|
|
enableSharedExecutables = false;
|
|
enableSharedLibraries = false;
|
|
});
|
|
};
|
|
|
|
# Use this rather than `rec { ... }` below for sake of overlays.
|
|
inherit (pkgs.haskell) compiler packages;
|
|
|
|
in {
|
|
lib = haskellLib;
|
|
|
|
package-list = callPackage ../development/haskell-modules/package-list.nix {};
|
|
|
|
compiler = {
|
|
|
|
ghc865Binary = callPackage ../development/compilers/ghc/8.6.5-binary.nix { };
|
|
|
|
ghc8102Binary = callPackage ../development/compilers/ghc/8.10.2-binary.nix {
|
|
llvmPackages = pkgs.llvmPackages_9;
|
|
};
|
|
|
|
ghc8102BinaryMinimal = callPackage ../development/compilers/ghc/8.10.2-binary.nix {
|
|
llvmPackages = pkgs.llvmPackages_9;
|
|
minimal = true;
|
|
};
|
|
|
|
ghc8107Binary = callPackage ../development/compilers/ghc/8.10.7-binary.nix {
|
|
llvmPackages = pkgs.llvmPackages_11;
|
|
};
|
|
|
|
ghc8107BinaryMinimal = callPackage ../development/compilers/ghc/8.10.7-binary.nix {
|
|
llvmPackages = pkgs.llvmPackages_11;
|
|
minimal = true;
|
|
};
|
|
|
|
ghc884 = callPackage ../development/compilers/ghc/8.8.4.nix {
|
|
bootPkgs =
|
|
# aarch64 ghc865Binary gets SEGVs due to haskell#15449 or similar
|
|
# Musl bindists do not exist for ghc 8.6.5, so we use 8.10.* for them
|
|
if stdenv.isAarch64 || stdenv.hostPlatform.isMusl then
|
|
packages.ghc8102BinaryMinimal
|
|
else
|
|
packages.ghc865Binary;
|
|
inherit (buildPackages.python3Packages) sphinx;
|
|
buildLlvmPackages = buildPackages.llvmPackages_7;
|
|
llvmPackages = pkgs.llvmPackages_7;
|
|
};
|
|
ghc8107 = callPackage ../development/compilers/ghc/8.10.7.nix {
|
|
bootPkgs =
|
|
# aarch64 ghc865Binary gets SEGVs due to haskell#15449 or similar
|
|
# the oldest ghc with aarch64-darwin support is 8.10.5
|
|
# Musl bindists do not exist for ghc 8.6.5, so we use 8.10.* for them
|
|
if stdenv.isAarch64 || stdenv.isAarch32 then
|
|
packages.ghc8107BinaryMinimal
|
|
else
|
|
packages.ghc8107Binary;
|
|
inherit (buildPackages.python3Packages) sphinx;
|
|
# Need to use apple's patched xattr until
|
|
# https://github.com/xattr/xattr/issues/44 and
|
|
# https://github.com/xattr/xattr/issues/55 are solved.
|
|
inherit (buildPackages.darwin) xattr autoSignDarwinBinariesHook;
|
|
buildLlvmPackages = buildPackages.llvmPackages_9;
|
|
llvmPackages = pkgs.llvmPackages_9;
|
|
};
|
|
ghc901 = callPackage ../development/compilers/ghc/9.0.1.nix {
|
|
bootPkgs =
|
|
# aarch64 ghc8107Binary exceeds max output size on hydra
|
|
# the oldest ghc with aarch64-darwin support is 8.10.5
|
|
if stdenv.isAarch64 || stdenv.isAarch32 then
|
|
packages.ghc8107BinaryMinimal
|
|
else
|
|
packages.ghc8107Binary;
|
|
inherit (buildPackages.python3Packages) sphinx;
|
|
buildLlvmPackages = buildPackages.llvmPackages_10;
|
|
llvmPackages = pkgs.llvmPackages_10;
|
|
};
|
|
ghc921 = callPackage ../development/compilers/ghc/9.2.1.nix {
|
|
bootPkgs =
|
|
# aarch64 ghc8107Binary exceeds max output size on hydra
|
|
if stdenv.isAarch64 || stdenv.isAarch32 then
|
|
packages.ghc8107BinaryMinimal
|
|
else
|
|
packages.ghc8107Binary;
|
|
inherit (buildPackages.python3Packages) sphinx;
|
|
# Need to use apple's patched xattr until
|
|
# https://github.com/xattr/xattr/issues/44 and
|
|
# https://github.com/xattr/xattr/issues/55 are solved.
|
|
inherit (buildPackages.darwin) xattr;
|
|
buildLlvmPackages = buildPackages.llvmPackages_10;
|
|
llvmPackages = pkgs.llvmPackages_10;
|
|
};
|
|
ghcHEAD = callPackage ../development/compilers/ghc/head.nix {
|
|
bootPkgs = packages.ghc901; # no binary yet
|
|
inherit (buildPackages.python3Packages) sphinx;
|
|
# Need to use apple's patched xattr until
|
|
# https://github.com/xattr/xattr/issues/44 and
|
|
# https://github.com/xattr/xattr/issues/55 are solved.
|
|
inherit (buildPackages.darwin) xattr;
|
|
buildLlvmPackages = buildPackages.llvmPackages_10;
|
|
llvmPackages = pkgs.llvmPackages_10;
|
|
libffi = pkgs.libffi;
|
|
};
|
|
|
|
ghcjs = compiler.ghcjs810;
|
|
ghcjs810 = callPackage ../development/compilers/ghcjs/8.10 {
|
|
bootPkgs = packages.ghc8107;
|
|
ghcjsSrcJson = ../development/compilers/ghcjs/8.10/git.json;
|
|
stage0 = ../development/compilers/ghcjs/8.10/stage0.nix;
|
|
};
|
|
|
|
# The integer-simple attribute set contains all the GHC compilers
|
|
# build with integer-simple instead of integer-gmp.
|
|
integer-simple = let
|
|
integerSimpleGhcNames = pkgs.lib.filter
|
|
(name: ! builtins.elem name integerSimpleExcludes)
|
|
(pkgs.lib.attrNames compiler);
|
|
in pkgs.recurseIntoAttrs (pkgs.lib.genAttrs
|
|
integerSimpleGhcNames
|
|
(name: compiler.${name}.override { enableIntegerSimple = true; }));
|
|
|
|
# Starting from GHC 9, integer-{simple,gmp} is replaced by ghc-bignum
|
|
# with "native" and "gmp" backends.
|
|
native-bignum = let
|
|
nativeBignumGhcNames = pkgs.lib.filter
|
|
(name: builtins.elem name nativeBignumIncludes)
|
|
(pkgs.lib.attrNames compiler);
|
|
in pkgs.recurseIntoAttrs (pkgs.lib.genAttrs
|
|
nativeBignumGhcNames
|
|
(name: compiler.${name}.override { enableNativeBignum = true; }));
|
|
};
|
|
|
|
# Default overrides that are applied to all package sets.
|
|
packageOverrides = self : super : {};
|
|
|
|
# Always get compilers from `buildPackages`
|
|
packages = let bh = buildPackages.haskell; in {
|
|
|
|
ghc865Binary = callPackage ../development/haskell-modules {
|
|
buildHaskellPackages = bh.packages.ghc865Binary;
|
|
ghc = bh.compiler.ghc865Binary;
|
|
compilerConfig = callPackage ../development/haskell-modules/configuration-ghc-8.6.x.nix { };
|
|
packageSetConfig = bootstrapPackageSet;
|
|
};
|
|
ghc8102Binary = callPackage ../development/haskell-modules {
|
|
buildHaskellPackages = bh.packages.ghc8102Binary;
|
|
ghc = bh.compiler.ghc8102Binary;
|
|
compilerConfig = callPackage ../development/haskell-modules/configuration-ghc-8.10.x.nix { };
|
|
packageSetConfig = bootstrapPackageSet;
|
|
};
|
|
ghc8102BinaryMinimal = callPackage ../development/haskell-modules {
|
|
buildHaskellPackages = bh.packages.ghc8102BinaryMinimal;
|
|
ghc = bh.compiler.ghc8102BinaryMinimal;
|
|
compilerConfig = callPackage ../development/haskell-modules/configuration-ghc-8.10.x.nix { };
|
|
packageSetConfig = bootstrapPackageSet;
|
|
};
|
|
ghc8107Binary = callPackage ../development/haskell-modules {
|
|
buildHaskellPackages = bh.packages.ghc8107Binary;
|
|
ghc = bh.compiler.ghc8107Binary;
|
|
compilerConfig = callPackage ../development/haskell-modules/configuration-ghc-8.10.x.nix { };
|
|
packageSetConfig = bootstrapPackageSet;
|
|
};
|
|
ghc8107BinaryMinimal = callPackage ../development/haskell-modules {
|
|
buildHaskellPackages = bh.packages.ghc8107BinaryMinimal;
|
|
ghc = bh.compiler.ghc8107BinaryMinimal;
|
|
compilerConfig = callPackage ../development/haskell-modules/configuration-ghc-8.10.x.nix { };
|
|
packageSetConfig = bootstrapPackageSet;
|
|
};
|
|
ghc884 = callPackage ../development/haskell-modules {
|
|
buildHaskellPackages = bh.packages.ghc884;
|
|
ghc = bh.compiler.ghc884;
|
|
compilerConfig = callPackage ../development/haskell-modules/configuration-ghc-8.8.x.nix { };
|
|
};
|
|
ghc8107 = callPackage ../development/haskell-modules {
|
|
buildHaskellPackages = bh.packages.ghc8107;
|
|
ghc = bh.compiler.ghc8107;
|
|
compilerConfig = callPackage ../development/haskell-modules/configuration-ghc-8.10.x.nix { };
|
|
};
|
|
ghc901 = callPackage ../development/haskell-modules {
|
|
buildHaskellPackages = bh.packages.ghc901;
|
|
ghc = bh.compiler.ghc901;
|
|
compilerConfig = callPackage ../development/haskell-modules/configuration-ghc-9.0.x.nix { };
|
|
};
|
|
ghc921 = callPackage ../development/haskell-modules {
|
|
buildHaskellPackages = bh.packages.ghc921;
|
|
ghc = bh.compiler.ghc921;
|
|
compilerConfig = callPackage ../development/haskell-modules/configuration-ghc-9.2.x.nix { };
|
|
};
|
|
ghcHEAD = callPackage ../development/haskell-modules {
|
|
buildHaskellPackages = bh.packages.ghcHEAD;
|
|
ghc = bh.compiler.ghcHEAD;
|
|
compilerConfig = callPackage ../development/haskell-modules/configuration-ghc-head.nix { };
|
|
};
|
|
|
|
ghcjs = packages.ghcjs810;
|
|
ghcjs810 = callPackage ../development/haskell-modules rec {
|
|
buildHaskellPackages = ghc.bootPkgs;
|
|
ghc = bh.compiler.ghcjs810;
|
|
compilerConfig = callPackage ../development/haskell-modules/configuration-ghc-8.10.x.nix { };
|
|
packageSetConfig = callPackage ../development/haskell-modules/configuration-ghcjs.nix { };
|
|
};
|
|
|
|
# The integer-simple attribute set contains package sets for all the GHC compilers
|
|
# using integer-simple instead of integer-gmp.
|
|
integer-simple = let
|
|
integerSimpleGhcNames = pkgs.lib.filter
|
|
(name: ! builtins.elem name integerSimpleExcludes)
|
|
(pkgs.lib.attrNames packages);
|
|
in pkgs.lib.genAttrs integerSimpleGhcNames (name: packages.${name}.override {
|
|
ghc = bh.compiler.integer-simple.${name};
|
|
buildHaskellPackages = bh.packages.integer-simple.${name};
|
|
overrides = _self : _super : {
|
|
integer-simple = null;
|
|
integer-gmp = null;
|
|
};
|
|
});
|
|
|
|
native-bignum = let
|
|
nativeBignumGhcNames = pkgs.lib.filter
|
|
(name: builtins.elem name nativeBignumIncludes)
|
|
(pkgs.lib.attrNames compiler);
|
|
in pkgs.lib.genAttrs nativeBignumGhcNames (name: packages.${name}.override {
|
|
ghc = bh.compiler.native-bignum.${name};
|
|
buildHaskellPackages = bh.packages.native-bignum.${name};
|
|
overrides = _self : _super : {
|
|
integer-gmp = null;
|
|
};
|
|
});
|
|
};
|
|
}
|