mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-14 16:46:09 +00:00
01d4e2fe33
After making `ffmpeg` point to the latest `ffmpeg_4`, all packages that used `ffmpeg` without requiring a specific version now use ffmpeg_3 explicitly so they shouldn't change.
65 lines
1.9 KiB
Nix
65 lines
1.9 KiB
Nix
{ stdenv, fetchurl, fetchFromGitHub, makeWrapper
|
|
, meson
|
|
, ninja
|
|
, pkg-config
|
|
, fetchpatch
|
|
|
|
, platform-tools
|
|
, ffmpeg_3
|
|
, SDL2
|
|
}:
|
|
|
|
let
|
|
version = "1.14";
|
|
prebuilt_server = fetchurl {
|
|
url = "https://github.com/Genymobile/scrcpy/releases/download/v${version}/scrcpy-server-v${version}";
|
|
sha256 = "082n57a9lw39lfjxybgim09qf0id9m0rpfb3zmqng58fp2i1h6qx";
|
|
};
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
pname = "scrcpy";
|
|
inherit version;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "Genymobile";
|
|
repo = pname;
|
|
rev = "v${version}";
|
|
sha256 = "1w06gsvgjdbpb9lvvhpjwmysxjl0daiigjfh3cxfgz88447bgw7j";
|
|
};
|
|
|
|
# postPatch:
|
|
# screen.c: When run without a hardware accelerator, this allows the command to continue working rather than failing unexpectedly.
|
|
# This can happen when running on non-NixOS because then scrcpy seems to have a hard time using the host OpenGL-supporting hardware.
|
|
# It would be better to fix the OpenGL problem, but that seems much more intrusive.
|
|
postPatch = ''
|
|
substituteInPlace app/src/screen.c \
|
|
--replace "SDL_RENDERER_ACCELERATED" "SDL_RENDERER_ACCELERATED || SDL_RENDERER_SOFTWARE"
|
|
'';
|
|
|
|
nativeBuildInputs = [ makeWrapper meson ninja pkg-config ];
|
|
|
|
buildInputs = [ ffmpeg_3 SDL2 ];
|
|
|
|
# Manually install the server jar to prevent Meson from "fixing" it
|
|
preConfigure = ''
|
|
echo -n > server/meson.build
|
|
'';
|
|
|
|
mesonFlags = [ "-Doverride_server_path=${prebuilt_server}" ];
|
|
postInstall = ''
|
|
mkdir -p "$out/share/scrcpy"
|
|
ln -s "${prebuilt_server}" "$out/share/scrcpy/scrcpy-server"
|
|
|
|
# runtime dep on `adb` to push the server
|
|
wrapProgram "$out/bin/scrcpy" --prefix PATH : "${platform-tools}/bin"
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Display and control Android devices over USB or TCP/IP";
|
|
homepage = "https://github.com/Genymobile/scrcpy";
|
|
license = licenses.asl20;
|
|
platforms = platforms.unix;
|
|
maintainers = with maintainers; [ deltaevo lukeadams ];
|
|
};
|
|
}
|