mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-25 03:17:13 +00:00
be006eab1f
By generating a version-5 GUID based on $out (which contains the derivation hash) and preventing isohybrid from overwriting the GPT table (which already is populated correctly by xorriso). Tested by: * booting from USB disk on a UEFI system * booting from USB disk on a non-UEFI system * booting from CD on a UEFI system * booting from CD on a non-UEFI system * booting from CD on an OSX system Also tested that "nix-build ./nixos/release-combined.nix -A nixos.iso_minimal.x86_64-linux -I nixpkgs=~/nixpkgs-r13y --check" now succeeds. Fixes #74047
66 lines
2 KiB
Nix
66 lines
2 KiB
Nix
{ stdenv, closureInfo, xorriso, syslinux, libossp_uuid
|
|
|
|
, # The file name of the resulting ISO image.
|
|
isoName ? "cd.iso"
|
|
|
|
, # The files and directories to be placed in the ISO file system.
|
|
# This is a list of attribute sets {source, target} where `source'
|
|
# is the file system object (regular file or directory) to be
|
|
# grafted in the file system at path `target'.
|
|
contents
|
|
|
|
, # In addition to `contents', the closure of the store paths listed
|
|
# in `storeContents' are also placed in the Nix store of the CD.
|
|
# This is a list of attribute sets {object, symlink} where `object'
|
|
# is a store path whose closure will be copied, and `symlink' is a
|
|
# symlink to `object' that will be added to the CD.
|
|
storeContents ? []
|
|
|
|
, # Whether this should be an El-Torito bootable CD.
|
|
bootable ? false
|
|
|
|
, # Whether this should be an efi-bootable El-Torito CD.
|
|
efiBootable ? false
|
|
|
|
, # Whether this should be an hybrid CD (bootable from USB as well as CD).
|
|
usbBootable ? false
|
|
|
|
, # The path (in the ISO file system) of the boot image.
|
|
bootImage ? ""
|
|
|
|
, # The path (in the ISO file system) of the efi boot image.
|
|
efiBootImage ? ""
|
|
|
|
, # The path (outside the ISO file system) of the isohybrid-mbr image.
|
|
isohybridMbrImage ? ""
|
|
|
|
, # Whether to compress the resulting ISO image with zstd.
|
|
compressImage ? false, zstd
|
|
|
|
, # The volume ID.
|
|
volumeID ? ""
|
|
}:
|
|
|
|
assert bootable -> bootImage != "";
|
|
assert efiBootable -> efiBootImage != "";
|
|
assert usbBootable -> isohybridMbrImage != "";
|
|
|
|
stdenv.mkDerivation {
|
|
name = isoName;
|
|
builder = ./make-iso9660-image.sh;
|
|
buildInputs = [ xorriso syslinux zstd libossp_uuid ];
|
|
|
|
inherit isoName bootable bootImage compressImage volumeID efiBootImage efiBootable isohybridMbrImage usbBootable;
|
|
|
|
# !!! should use XML.
|
|
sources = map (x: x.source) contents;
|
|
targets = map (x: x.target) contents;
|
|
|
|
# !!! should use XML.
|
|
objects = map (x: x.object) storeContents;
|
|
symlinks = map (x: x.symlink) storeContents;
|
|
|
|
# For obtaining the closure of `storeContents'.
|
|
closureInfo = closureInfo { rootPaths = map (x: x.object) storeContents; };
|
|
}
|