mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-25 03:17:13 +00:00
6f6c06adc1
This reflects upstream versioning change, and allows us to replace 4.0 with 4.1 (which is now a minor revision) without changing the attribute name. Thanks to @vcunat for the idea.
57 lines
1.9 KiB
Nix
57 lines
1.9 KiB
Nix
{ stdenv, fetch, cmake, libxml2, libedit, llvm, version, release_version, clang-tools-extra_src, python }:
|
|
|
|
let
|
|
gcc = if stdenv.cc.isGNU then stdenv.cc.cc else stdenv.cc.cc.gcc;
|
|
self = stdenv.mkDerivation {
|
|
name = "clang-${version}";
|
|
|
|
unpackPhase = ''
|
|
unpackFile ${fetch "cfe" "1lsdyrz82vyrsc7k0ah1zmzzan61s5kakxrkxgfbmklp3pclfkwp"}
|
|
mv cfe-${version}* clang
|
|
sourceRoot=$PWD/clang
|
|
unpackFile ${clang-tools-extra_src}
|
|
mv clang-tools-extra-* $sourceRoot/tools/extra
|
|
'';
|
|
|
|
buildInputs = [ cmake libedit libxml2 llvm python ];
|
|
|
|
cmakeFlags = [
|
|
"-DCMAKE_CXX_FLAGS=-std=c++11"
|
|
] ++
|
|
# Maybe with compiler-rt this won't be needed?
|
|
(stdenv.lib.optional stdenv.isLinux "-DGCC_INSTALL_PREFIX=${gcc}") ++
|
|
(stdenv.lib.optional (stdenv.cc.libc != null) "-DC_INCLUDE_DIRS=${stdenv.cc.libc}/include");
|
|
|
|
patches = [ ./purity.patch ];
|
|
|
|
postPatch = ''
|
|
sed -i -e 's/Args.hasArg(options::OPT_nostdlibinc)/true/' lib/Driver/Tools.cpp
|
|
sed -i -e 's/DriverArgs.hasArg(options::OPT_nostdlibinc)/true/' lib/Driver/ToolChains.cpp
|
|
'';
|
|
|
|
# Clang expects to find LLVMgold in its own prefix
|
|
# Clang expects to find sanitizer libraries in its own prefix
|
|
postInstall = ''
|
|
ln -sv ${llvm}/lib/LLVMgold.so $out/lib
|
|
ln -sv ${llvm}/lib/clang/${release_version}/lib $out/lib/clang/${release_version}/
|
|
ln -sv $out/bin/clang $out/bin/cpp
|
|
'';
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
passthru = {
|
|
lib = self; # compatibility with gcc, so that `stdenv.cc.cc.lib` works on both
|
|
isClang = true;
|
|
} // stdenv.lib.optionalAttrs stdenv.isLinux {
|
|
inherit gcc;
|
|
};
|
|
|
|
meta = {
|
|
description = "A c, c++, objective-c, and objective-c++ frontend for the llvm compiler";
|
|
homepage = http://llvm.org/;
|
|
license = stdenv.lib.licenses.ncsa;
|
|
platforms = stdenv.lib.platforms.all;
|
|
};
|
|
};
|
|
in self
|