mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-25 03:17:13 +00:00
b1cd08246f
This allows you to turn on debug infor for all the beam packages in the system with a single change at the top level. This is required for debugging and dialyzer work. It also allows you to switch it on on a package by package basis.
98 lines
2.1 KiB
Nix
98 lines
2.1 KiB
Nix
{ stdenv, writeText, erlang, perl, which, gitMinimal, wget, lib }:
|
|
|
|
{ name, version
|
|
, src
|
|
, setupHook ? null
|
|
, buildInputs ? []
|
|
, beamDeps ? []
|
|
, postPatch ? ""
|
|
, compilePorts ? false
|
|
, installPhase ? null
|
|
, buildPhase ? null
|
|
, configurePhase ? null
|
|
, meta ? {}
|
|
, enableDebugInfo ? false
|
|
, ... }@attrs:
|
|
|
|
with stdenv.lib;
|
|
|
|
let
|
|
debugInfoFlag = lib.optionalString (enableDebugInfo || erlang.debugInfo) "+debug_info";
|
|
|
|
shell = drv: stdenv.mkDerivation {
|
|
name = "interactive-shell-${drv.name}";
|
|
buildInputs = [ drv ];
|
|
};
|
|
|
|
pkg = self: stdenv.mkDerivation ( attrs // {
|
|
app_name = "${name}";
|
|
name = "${name}-${version}";
|
|
inherit version;
|
|
|
|
dontStrip = true;
|
|
|
|
inherit src;
|
|
|
|
setupHook = if setupHook == null
|
|
then writeText "setupHook.sh" ''
|
|
addToSearchPath ERL_LIBS "$1/lib/erlang/lib"
|
|
''
|
|
else setupHook;
|
|
|
|
buildInputs = [ erlang perl which gitMinimal wget ];
|
|
propagatedBuildInputs = beamDeps;
|
|
|
|
configurePhase = if configurePhase == null
|
|
then ''
|
|
runHook preConfigure
|
|
|
|
# We shouldnt need to do this, but it seems at times there is a *.app in
|
|
# the repo/package. This ensures we start from a clean slate
|
|
make SKIP_DEPS=1 clean
|
|
|
|
runHook postConfigure
|
|
''
|
|
else configurePhase;
|
|
|
|
buildPhase = if buildPhase == null
|
|
then ''
|
|
runHook preBuild
|
|
|
|
make SKIP_DEPS=1 ERL_OPTS="$ERL_OPTS ${debugInfoFlag}"
|
|
|
|
runHook postBuild
|
|
''
|
|
else buildPhase;
|
|
|
|
installPhase = if installPhase == null
|
|
then ''
|
|
runHook preInstall
|
|
|
|
mkdir -p $out/lib/erlang/lib/${name}
|
|
cp -r ebin $out/lib/erlang/lib/${name}/
|
|
cp -r src $out/lib/erlang/lib/${name}/
|
|
|
|
if [ -d include ]; then
|
|
cp -r include $out/lib/erlang/lib/${name}/
|
|
fi
|
|
|
|
if [ -d priv ]; then
|
|
cp -r priv $out/lib/erlang/lib/${name}/
|
|
fi
|
|
|
|
if [ -d doc ]; then
|
|
cp -r doc $out/lib/erlang/lib/${name}/
|
|
fi
|
|
|
|
runHook postInstall
|
|
''
|
|
else installPhase;
|
|
|
|
passthru = {
|
|
packageName = name;
|
|
env = shell self;
|
|
inherit beamDeps;
|
|
};
|
|
});
|
|
in fix pkg
|