mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-25 03:17:13 +00:00
c14f3e4039
"Capture image from USB webcam at a specified interval" I apply patches from Debian to make it build with V4L2 (instead of v1 API) and fix some warnings/bugs. Source code is also downloaded from Debian, as uvccapture homepage is unavailable. Homepage: http://linux-uvc.berlios.de/ (seems to have vanished...)
52 lines
1.3 KiB
Nix
52 lines
1.3 KiB
Nix
{ stdenv, fetchurl, libjpeg }:
|
|
|
|
let
|
|
debianPatches = fetchurl {
|
|
url = "mirror://debian/pool/main/u/uvccapture/uvccapture_0.5-3.debian.tar.gz";
|
|
sha256 = "0m29by13nw1r8sch366qzdxg5rsd1k766kqg1nj2pdb8f7pwjh9r";
|
|
};
|
|
|
|
in
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "uvccapture-0.5";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://debian/pool/main/u/uvccapture/uvccapture_0.5.orig.tar.gz";
|
|
sha256 = "1b3akkcmr3brbf93akr8xi20w8zqf2g0qfq928500wy04qi6jqpi";
|
|
};
|
|
|
|
buildInputs = [ libjpeg ];
|
|
|
|
patchPhase = ''
|
|
tar xvf "${debianPatches}"
|
|
for fname in debian/patches/fix_videodev_include_FTBFS.patch \
|
|
debian/patches/warnings.patch \
|
|
debian/patches/numbuffers.patch
|
|
do
|
|
echo "Applying patch $fname"
|
|
patch < "$fname"
|
|
done
|
|
'';
|
|
|
|
makeFlagsArray = [ "PREFIX=$(out)/bin/" ];
|
|
|
|
preInstall = ''
|
|
mkdir -p "$out/bin"
|
|
'';
|
|
|
|
# Upstream has no man page, install one from Debian
|
|
postInstall = ''
|
|
mkdir -p "$out/share/man/man1"
|
|
cp -v debian/uvccapture.1 "$out/share/man/man1/"
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Capture image from USB webcam at a specified interval";
|
|
homepage = http://linux-uvc.berlios.de/;
|
|
license = licenses.gpl2Plus;
|
|
platforms = platforms.linux;
|
|
maintainers = [ maintainers.bjornfor ];
|
|
};
|
|
}
|