mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-21 05:25:38 +00:00
ced21f5e1a
The `buildPython*` function computes name from `pname` and `version`. This change removes `name` attribute from all expressions in `pkgs/development/python-modules`. While at it, some other minor changes were made as well, such as replacing `fetchurl` calls with `fetchPypi`.
44 lines
1.1 KiB
Nix
44 lines
1.1 KiB
Nix
{ stdenv, buildPythonPackage, fetchFromGitHub, pytest, nose, libarchive, glibcLocales
|
|
# unrar is non-free software
|
|
, useUnrar ? false, unrar
|
|
}:
|
|
|
|
assert useUnrar -> unrar != null;
|
|
assert !useUnrar -> libarchive != null;
|
|
|
|
buildPythonPackage rec {
|
|
pname = "rarfile";
|
|
version = "3.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "markokr";
|
|
repo = "rarfile";
|
|
rev = "rarfile_3_0";
|
|
sha256 = "07yliz6p1bxzhipnrgz133gl8laic35gl4rqfay7f1vc384ch7sn";
|
|
};
|
|
buildInputs = [ pytest nose glibcLocales ];
|
|
|
|
prePatch = ''
|
|
substituteInPlace rarfile.py \
|
|
'' + (if useUnrar then
|
|
''--replace 'UNRAR_TOOL = "unrar"' "UNRAR_TOOL = \"${unrar}/bin/unrar\""
|
|
''
|
|
else
|
|
''--replace 'ALT_TOOL = "bsdtar"' "ALT_TOOL = \"${libarchive}/bin/bsdtar\""
|
|
'')
|
|
+ ''
|
|
'';
|
|
# the tests only work with the standard unrar package
|
|
doCheck = useUnrar;
|
|
LC_ALL = "en_US.UTF-8";
|
|
checkPhase = ''
|
|
py.test test -k "not test_printdir"
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "RAR archive reader for Python";
|
|
homepage = https://github.com/markokr/rarfile;
|
|
license = licenses.isc;
|
|
};
|
|
}
|