mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-09-11 15:08:33 +01:00
582354d3b6
The semantic difference between `encode` and `to` is not apparent. Users are likely to confuse both functions (which leads to unexpected error messages about the wrong types). Like in `generators.nix`, all functions should be prefixed by `to`. Furthermore, converting to a string depends on the target context. In this case, it’s a POSIX shell, so we should name it that (compare `escapeShellArg` in `strings.nix`). We can later add versions that escape for embedding in e.g. python scripts or similar.
79 lines
2.1 KiB
Nix
79 lines
2.1 KiB
Nix
{ lib }:
|
|
|
|
rec {
|
|
/* Automatically convert an attribute set to command-line options.
|
|
|
|
This helps protect against malformed command lines and also to reduce
|
|
boilerplate related to command-line construction for simple use cases.
|
|
|
|
`toGNUCommandLine` returns a list of nix strings.
|
|
`toGNUCommandLineShell` returns an escaped shell string.
|
|
|
|
Example:
|
|
toGNUCommandLine
|
|
{ }
|
|
{ data = builtins.toJSON { id = 0; };
|
|
|
|
X = "PUT";
|
|
|
|
retry = 3;
|
|
|
|
retry-delay = null;
|
|
|
|
url = [ "https://example.com/foo" "https://example.com/bar" ];
|
|
|
|
silent = false;
|
|
|
|
verbose = true;
|
|
};
|
|
=> [ "-X" "PUT" "--data" "{\"id\":0}" "--retry" "3" "--url" "https://example.com/foo" "--url" "https://example.com/bar" "--verbose" ]
|
|
|
|
toGNUCommandLineShell
|
|
{ }
|
|
{ data = builtins.toJSON { id = 0; };
|
|
|
|
X = "PUT";
|
|
|
|
retry = 3;
|
|
|
|
retry-delay = null;
|
|
|
|
url = [ "https://example.com/foo" "https://example.com/bar" ];
|
|
|
|
silent = false;
|
|
|
|
verbose = true;
|
|
};
|
|
=> "'-X' 'PUT' '--data' '{\"id\":0}' '--retry' '3' '--url' 'https://example.com/foo' '--url' 'https://example.com/bar' '--verbose'"
|
|
|
|
*/
|
|
toGNUCommandLineShell =
|
|
options: attrs: lib.escapeShellArgs (toGNUCommandLine options attrs);
|
|
|
|
toGNUCommandLine =
|
|
{ renderKey ?
|
|
key: if builtins.stringLength key == 1 then "-${key}" else "--${key}"
|
|
|
|
, renderOption ?
|
|
key: value:
|
|
if value == null
|
|
then []
|
|
else [ (renderKey key) (builtins.toString value) ]
|
|
|
|
, renderBool ? key: value: lib.optional value (renderKey key)
|
|
|
|
, renderList ? key: value: lib.concatMap (renderOption key) value
|
|
}:
|
|
options:
|
|
let
|
|
render = key: value:
|
|
if builtins.isBool value
|
|
then renderBool key value
|
|
else if builtins.isList value
|
|
then renderList key value
|
|
else renderOption key value;
|
|
|
|
in
|
|
builtins.concatLists (lib.mapAttrsToList render options);
|
|
}
|