mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-25 03:17:13 +00:00
0e1bf2f254
- nixpkgs-fmt - use pname and version - use multiline for prePatch to make tree-wide modifications easier - remove global `with lib;` - update homepage to dwm page - copy description from git repo - add longDescription - remove unused config.dwm.patches
47 lines
1.5 KiB
Nix
47 lines
1.5 KiB
Nix
{ lib, stdenv, fetchurl, libX11, libXinerama, libXft, writeText, patches ? [ ], conf ? null}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "dwm";
|
|
version = "6.2";
|
|
|
|
src = fetchurl {
|
|
url = "https://dl.suckless.org/dwm/${pname}-${version}.tar.gz";
|
|
sha256 = "03hirnj8saxnsfqiszwl2ds7p0avg20izv9vdqyambks00p2x44p";
|
|
};
|
|
|
|
buildInputs = [ libX11 libXinerama libXft ];
|
|
|
|
prePatch = ''
|
|
sed -i "s@/usr/local@$out@" config.mk
|
|
'';
|
|
|
|
# Allow users set their own list of patches
|
|
inherit patches;
|
|
|
|
# Allow users to set the config.def.h file containing the configuration
|
|
postPatch =
|
|
let
|
|
configFile =
|
|
if lib.isDerivation conf || builtins.isPath conf
|
|
then conf else writeText "config.def.h" conf;
|
|
in
|
|
lib.optionalString (conf != null) "cp ${configFile} config.def.h";
|
|
|
|
meta = with lib; {
|
|
homepage = "https://dwm.suckless.org/";
|
|
description = "An extremely fast, small, and dynamic window manager for X";
|
|
longDescription = ''
|
|
dwm is a dynamic window manager for X. It manages windows in tiled,
|
|
monocle and floating layouts. All of the layouts can be applied
|
|
dynamically, optimising the environment for the application in use and the
|
|
task performed.
|
|
Windows are grouped by tags. Each window can be tagged with one or
|
|
multiple tags. Selecting certain tags displays all windows with these
|
|
tags.
|
|
'';
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ viric ];
|
|
platforms = platforms.all;
|
|
};
|
|
}
|