1
0
Fork 1
mirror of https://github.com/NixOS/nixpkgs.git synced 2024-09-11 15:08:33 +01:00
nixpkgs/pkgs/os-specific/linux/nvidia-x11/default.nix
Vladimír Čunát 25351012b2 nvidia: fix problems with -glsi and glx
..by generalizing the build script.
Obsoletes #3699, and it should finally fix problems around 816d971a.
2014-08-20 23:37:41 +02:00

62 lines
1.9 KiB
Nix

{ stdenv, fetchurl, kernel ? null, xlibs, zlib, perl
, gtk, atk, pango, glib, gdk_pixbuf
, # Whether to build the libraries only (i.e. not the kernel module or
# nvidia-settings). Used to support 32-bit binaries on 64-bit
# Linux.
libsOnly ? false
}:
with stdenv.lib;
assert (!libsOnly) -> kernel != null;
let
versionNumber = "340.32";
inherit (stdenv.lib) makeLibraryPath;
in
stdenv.mkDerivation {
name = "nvidia-x11-${versionNumber}${optionalString (!libsOnly) "-${kernel.version}"}";
builder = ./builder.sh;
src =
if stdenv.system == "i686-linux" then
fetchurl {
url = "http://us.download.nvidia.com/XFree86/Linux-x86/${versionNumber}/NVIDIA-Linux-x86-${versionNumber}.run";
sha256 = "1xcm8czz4bmnlzkl3al58flw6jmbrg1y77cxjjdjqcsvbk1qj10x";
}
else if stdenv.system == "x86_64-linux" then
fetchurl {
url = "http://us.download.nvidia.com/XFree86/Linux-x86_64/${versionNumber}/NVIDIA-Linux-x86_64-${versionNumber}-no-compat32.run";
sha256 = "1nfrpx73817y1z0wkqqh02xjg65r0f05h9801mqm8ki2gxqv9vq0";
}
else throw "nvidia-x11 does not support platform ${stdenv.system}";
inherit versionNumber libsOnly;
kernel = if libsOnly then null else kernel.dev;
dontStrip = true;
glPath = makeLibraryPath [xlibs.libXext xlibs.libX11 xlibs.libXrandr];
cudaPath = makeLibraryPath [zlib stdenv.gcc.gcc];
openclPath = makeLibraryPath [zlib];
allLibPath = makeLibraryPath [xlibs.libXext xlibs.libX11 xlibs.libXrandr zlib stdenv.gcc.gcc];
programPath = optionalString (!libsOnly) (makeLibraryPath
[ gtk atk pango glib gdk_pixbuf xlibs.libXv ] );
buildInputs = [ perl ];
meta = with stdenv.lib.meta; {
homepage = http://www.nvidia.com/object/unix.html;
description = "X.org driver and kernel module for NVIDIA graphics cards";
license = licenses.unfreeRedistributable;
platforms = platforms.linux;
maintainers = [ maintainers.vcunat ];
};
}