mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-25 03:17:13 +00:00
a229933de6
Semi-automatic update generated by https://github.com/ryantm/nixpkgs-update tools. This update was made based on information from https://repology.org/metapackage/opensubdiv/versions.
55 lines
1.6 KiB
Nix
55 lines
1.6 KiB
Nix
{ lib, stdenv, fetchFromGitHub, cmake, pkgconfig, xorg, libGLU
|
||
, libGL, glew, ocl-icd, python3
|
||
, cudaSupport ? false, cudatoolkit
|
||
, darwin
|
||
}:
|
||
|
||
stdenv.mkDerivation rec {
|
||
name = "opensubdiv-${version}";
|
||
version = "3.3.3";
|
||
|
||
src = fetchFromGitHub {
|
||
owner = "PixarAnimationStudios";
|
||
repo = "OpenSubdiv";
|
||
rev = "v${lib.replaceChars ["."] ["_"] version}";
|
||
sha256 = "1rld4hgl9yrbnk5sd6bhvnm8jdnqq09hq93hrmx0nhccccximi9z";
|
||
};
|
||
|
||
outputs = [ "out" "dev" ];
|
||
|
||
buildInputs =
|
||
[ cmake pkgconfig libGLU libGL python3
|
||
# FIXME: these are not actually needed, but the configure script wants them.
|
||
glew xorg.libX11 xorg.libXrandr xorg.libXxf86vm xorg.libXcursor
|
||
xorg.libXinerama xorg.libXi
|
||
]
|
||
++ lib.optional (!stdenv.isDarwin) ocl-icd
|
||
++ lib.optionals stdenv.isDarwin (with darwin.apple_sdk.frameworks; [OpenCL Cocoa CoreVideo IOKit AppKit AGL ])
|
||
++ lib.optional cudaSupport cudatoolkit;
|
||
|
||
cmakeFlags =
|
||
[ "-DNO_TUTORIALS=1"
|
||
"-DNO_REGRESSION=1"
|
||
"-DNO_EXAMPLES=1"
|
||
"-DNO_METAL=1" # don’t have metal in apple sdk
|
||
] ++ lib.optionals (!stdenv.isDarwin) [
|
||
"-DGLEW_INCLUDE_DIR=${glew.dev}/include"
|
||
"-DGLEW_LIBRARY=${glew.dev}/lib"
|
||
] ++ lib.optionals cudaSupport [
|
||
"-DOSD_CUDA_NVCC_FLAGS=--gpu-architecture=compute_30"
|
||
"-DCUDA_HOST_COMPILER=${cudatoolkit.cc}/bin/cc"
|
||
];
|
||
|
||
enableParallelBuilding = true;
|
||
|
||
postInstall = "rm $out/lib/*.a";
|
||
|
||
meta = {
|
||
description = "An Open-Source subdivision surface library";
|
||
homepage = http://graphics.pixar.com/opensubdiv;
|
||
platforms = lib.platforms.unix;
|
||
maintainers = [ lib.maintainers.eelco ];
|
||
license = lib.licenses.asl20;
|
||
};
|
||
}
|