mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-25 03:17:13 +00:00
0b45d5b8f9
Undefined symbols for architecture x86_64:
"_NSDefaultRunLoopMode", referenced from:
_uiMainStep in main.m.o
"_OBJC_CLASS_$_NSDate", referenced from:
objc-class-ref in main.m.o
"_OBJC_CLASS_$_NSDictionary", referenced from:
objc-class-ref in multilineentry.m.o
"_OBJC_CLASS_$_NSMutableArray", referenced from:
objc-class-ref in alloc.m.o
objc-class-ref in box.m.o
objc-class-ref in menu.m.o
objc-class-ref in radiobuttons.m.o
objc-class-ref in tab.m.o
ld: symbol(s) not found for architecture x86_64
54 lines
1.9 KiB
Nix
54 lines
1.9 KiB
Nix
{ stdenv, fetchgit, cmake, pkgconfig, gtk3, cf-private, Cocoa }:
|
|
|
|
let
|
|
shortName = "libui";
|
|
version = "3.1a";
|
|
backend = if stdenv.isDarwin then "darwin" else "unix";
|
|
in
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "${shortName}-${version}";
|
|
src = fetchgit {
|
|
url = "https://github.com/andlabs/libui.git";
|
|
rev = "6ebdc96b93273c3cedf81159e7843025caa83058";
|
|
sha256 = "1lpbfa298c61aarlzgp7vghrmxg1274pzxh1j9isv8x758gk6mfn";
|
|
};
|
|
|
|
nativeBuildInputs = [ cmake pkgconfig ];
|
|
buildInputs = stdenv.lib.optional stdenv.isLinux gtk3
|
|
++ stdenv.lib.optionals stdenv.isDarwin [ Cocoa cf-private /* For NSDefaultRunLoopMode */ ];
|
|
|
|
preConfigure = stdenv.lib.optionalString stdenv.isDarwin ''
|
|
sed -i 's/set(CMAKE_OSX_DEPLOYMENT_TARGET "10.8")//' ./CMakeLists.txt
|
|
'';
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/{include,lib}
|
|
mkdir -p $out/lib/pkgconfig
|
|
'' + stdenv.lib.optionalString stdenv.isLinux ''
|
|
mv ./out/${shortName}.so.0 $out/lib/
|
|
ln -s $out/lib/${shortName}.so.0 $out/lib/${shortName}.so
|
|
'' + stdenv.lib.optionalString stdenv.isDarwin ''
|
|
mv ./out/${shortName}.A.dylib $out/lib/
|
|
ln -s $out/lib/${shortName}.A.dylib $out/lib/${shortName}.dylib
|
|
'' + ''
|
|
cp $src/ui.h $out/include
|
|
cp $src/ui_${backend}.h $out/include
|
|
|
|
cp ${./libui.pc} $out/lib/pkgconfig/${shortName}.pc
|
|
substituteInPlace $out/lib/pkgconfig/${shortName}.pc \
|
|
--subst-var-by out $out \
|
|
--subst-var-by version "${version}"
|
|
'';
|
|
postInstall = stdenv.lib.optionalString stdenv.isDarwin ''
|
|
install_name_tool -id $out/lib/${shortName}.A.dylib $out/lib/${shortName}.A.dylib
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = https://github.com/andlabs/libui;
|
|
description = "Simple and portable (but not inflexible) GUI library in C that uses the native GUI technologies of each platform it supports.";
|
|
license = licenses.mit;
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|