mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-24 02:46:38 +00:00
4b5ae11f66
See: - https://dev.mysql.com/doc/relnotes/mysql/5.5/en/news-5-5-56.html - https://dev.mysql.com/doc/relnotes/mysql/5.5/en/news-5-5-56.html - https://dev.mysql.com/doc/relnotes/mysql/5.5/en/news-5-5-55.html - http://www.oracle.com/technetwork/security-advisory/cpujul2017-3236622.html Fixes: CVE-2017-3635 CVE-2017-3636 CVE-2017-3641 CVE-2017-3648 CVE-2017-3651 CVE-2017-3652 CVE-2017-3653
70 lines
2 KiB
Nix
70 lines
2 KiB
Nix
{ stdenv, fetchurl, cmake, bison, ncurses, openssl, readline, zlib, perl
|
|
, cctools, CoreServices }:
|
|
|
|
# Note: zlib is not required; MySQL can use an internal zlib.
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "mysql-${version}";
|
|
version = "5.5.57";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://mysql/MySQL-5.5/${name}.tar.gz";
|
|
sha256 = "113kynpfj45fffr62xack2657pds8mkhsgg77zj94ksj3qrbvhn1";
|
|
};
|
|
|
|
patches = if stdenv.isCygwin then [
|
|
./5.5.17-cygwin.patch
|
|
./5.5.17-export-symbols.patch
|
|
] else null;
|
|
|
|
preConfigure = stdenv.lib.optional stdenv.isDarwin ''
|
|
ln -s /bin/ps $TMPDIR/ps
|
|
export PATH=$PATH:$TMPDIR
|
|
'';
|
|
|
|
buildInputs = [ cmake bison ncurses openssl readline zlib ]
|
|
++ stdenv.lib.optionals stdenv.isDarwin [ perl cctools CoreServices ];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
cmakeFlags = [
|
|
"-DWITH_SSL=yes"
|
|
"-DWITH_READLINE=yes"
|
|
"-DWITH_EMBEDDED_SERVER=yes"
|
|
"-DWITH_ZLIB=yes"
|
|
"-DHAVE_IPV6=yes"
|
|
"-DMYSQL_UNIX_ADDR=/run/mysqld/mysqld.sock"
|
|
"-DMYSQL_DATADIR=/var/lib/mysql"
|
|
"-DINSTALL_SYSCONFDIR=etc/mysql"
|
|
"-DINSTALL_INFODIR=share/mysql/docs"
|
|
"-DINSTALL_MANDIR=share/man"
|
|
"-DINSTALL_PLUGINDIR=lib/mysql/plugin"
|
|
"-DINSTALL_SCRIPTDIR=bin"
|
|
"-DINSTALL_INCLUDEDIR=include/mysql"
|
|
"-DINSTALL_DOCREADMEDIR=share/mysql"
|
|
"-DINSTALL_SUPPORTFILESDIR=share/mysql"
|
|
"-DINSTALL_MYSQLSHAREDIR=share/mysql"
|
|
"-DINSTALL_DOCDIR=share/mysql/docs"
|
|
"-DINSTALL_SHAREDIR=share/mysql"
|
|
];
|
|
|
|
NIX_LDFLAGS = stdenv.lib.optionalString stdenv.isLinux "-lgcc_s";
|
|
|
|
prePatch = ''
|
|
sed -i -e "s|/usr/bin/libtool|libtool|" cmake/libutils.cmake
|
|
'';
|
|
postInstall = ''
|
|
sed -i -e "s|basedir=\"\"|basedir=\"$out\"|" $out/bin/mysql_install_db
|
|
rm -r $out/mysql-test $out/sql-bench $out/data "$out"/lib/*.a
|
|
rm $out/share/man/man1/mysql-test-run.pl.1
|
|
'';
|
|
|
|
passthru.mysqlVersion = "5.5";
|
|
|
|
meta = {
|
|
homepage = http://www.mysql.com/;
|
|
description = "The world's most popular open source database";
|
|
platforms = stdenv.lib.platforms.unix;
|
|
};
|
|
}
|