mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-18 19:51:17 +00:00
0a6e6cf7e6
this converts meta.doc into an md pointer, not an xml pointer. since we no longer need xml for manual chapters we can also remove support for manual chapters from md-to-db.sh since pandoc converts smart quotes to docbook quote elements and our nixos-render-docs does not we lose this distinction in the rendered output. that's probably not that bad, our stylesheet didn't make use of this anyway (and pre-23.05 versions of the chapters didn't use quote elements either). also updates the nixpkgs manual to clarify that option docs support all extensions (although it doesn't support headings at all, so heading anchors don't work by extension).
77 lines
2 KiB
Nix
77 lines
2 KiB
Nix
{ lib, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
maintainer = mkOptionType {
|
|
name = "maintainer";
|
|
check = email: elem email (attrValues lib.maintainers);
|
|
merge = loc: defs: listToAttrs (singleton (nameValuePair (last defs).file (last defs).value));
|
|
};
|
|
|
|
listOfMaintainers = types.listOf maintainer // {
|
|
# Returns list of
|
|
# { "module-file" = [
|
|
# "maintainer1 <first@nixos.org>"
|
|
# "maintainer2 <second@nixos.org>" ];
|
|
# }
|
|
merge = loc: defs:
|
|
zipAttrs
|
|
(flatten (imap1 (n: def: imap1 (m: def':
|
|
maintainer.merge (loc ++ ["[${toString n}-${toString m}]"])
|
|
[{ inherit (def) file; value = def'; }]) def.value) defs));
|
|
};
|
|
|
|
docFile = types.path // {
|
|
# Returns tuples of
|
|
# { file = "module location"; value = <path/to/doc.xml>; }
|
|
merge = loc: defs: defs;
|
|
};
|
|
in
|
|
|
|
{
|
|
options = {
|
|
meta = {
|
|
|
|
maintainers = mkOption {
|
|
type = listOfMaintainers;
|
|
internal = true;
|
|
default = [];
|
|
example = literalExpression ''[ lib.maintainers.all ]'';
|
|
description = lib.mdDoc ''
|
|
List of maintainers of each module. This option should be defined at
|
|
most once per module.
|
|
'';
|
|
};
|
|
|
|
doc = mkOption {
|
|
type = docFile;
|
|
internal = true;
|
|
example = "./meta.chapter.md";
|
|
description = lib.mdDoc ''
|
|
Documentation prologue for the set of options of each module. This
|
|
option should be defined at most once per module.
|
|
'';
|
|
};
|
|
|
|
buildDocsInSandbox = mkOption {
|
|
type = types.bool // {
|
|
merge = loc: defs: defs;
|
|
};
|
|
internal = true;
|
|
default = true;
|
|
description = lib.mdDoc ''
|
|
Whether to include this module in the split options doc build.
|
|
Disable if the module references `config`, `pkgs` or other module
|
|
arguments that cannot be evaluated as constants.
|
|
|
|
This option should be defined at most once per module.
|
|
'';
|
|
};
|
|
|
|
};
|
|
};
|
|
|
|
meta.maintainers = singleton lib.maintainers.pierron;
|
|
}
|