mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-17 18:34:41 +00:00
89023c38fc
I made a mistake merge. Reverting it inc778945806undid the state on master, but now I realize it crippled the git merge mechanism. As the merge contained a mix of commits from `master..staging-next` and other commits from `staging-next..staging`, it got the `staging-next` branch into a state that was difficult to recover. I reconstructed the "desired" state of staging-next tree by: - checking out the last commit of the problematic range:4effe769e2- `git rebase -i --preserve-merges a8a018ddc0` - dropping the mistaken merge commit and its revert from that range (while keeping reapplication from4effe769e2) - merging the last unaffected staging-next commit (803ca85c20) - fortunately no other commits have been pushed to staging-next yet - applying a diff on staging-next to get it into that state
49 lines
1.6 KiB
Nix
49 lines
1.6 KiB
Nix
{ stdenv, fetchurl, fetchpatch, pkgconfig, glib, autoreconfHook }:
|
|
|
|
let
|
|
cross = stdenv.hostPlatform != stdenv.buildPlatform;
|
|
in stdenv.mkDerivation (rec {
|
|
name = "gamin-0.1.10";
|
|
|
|
src = fetchurl {
|
|
url = "https://www.gnome.org/~veillard/gamin/sources/${name}.tar.gz";
|
|
sha256 = "18cr51y5qacvs2fc2p1bqv32rs8bzgs6l67zhasyl45yx055y218";
|
|
};
|
|
|
|
nativeBuildInputs = [ pkgconfig autoreconfHook ];
|
|
|
|
buildInputs = [ glib ];
|
|
|
|
# `_GNU_SOURCE' is needed, e.g., to get `struct ucred' from
|
|
# <sys/socket.h> with Glibc 2.9.
|
|
configureFlags = [
|
|
"--disable-debug"
|
|
"--without-python" # python3 not supported
|
|
"CPPFLAGS=-D_GNU_SOURCE"
|
|
];
|
|
|
|
patches = [ ./deadlock.patch ]
|
|
++ map fetchurl (import ./debian-patches.nix)
|
|
++ stdenv.lib.optional stdenv.cc.isClang ./returnval.patch
|
|
++ stdenv.lib.optional stdenv.hostPlatform.isMusl (fetchpatch {
|
|
name = "fix-pthread-mutex.patch";
|
|
url = "https://git.alpinelinux.org/aports/plain/main/gamin/fix-pthread-mutex.patch?h=3.4-stable&id=a1a836b089573752c1b0da7d144c0948b04e8ea8";
|
|
sha256 = "13igdbqsxb3sz0h417k6ifmq2n4siwqspj6slhc7fdl5wd1fxmdz";
|
|
}) ++ stdenv.lib.optional (cross) ./abstract-socket-namespace.patch ;
|
|
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = "https://people.gnome.org/~veillard/gamin/";
|
|
description = "A file and directory monitoring system";
|
|
maintainers = with maintainers; [ lovek323 ];
|
|
license = licenses.gpl2;
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|
|
|
|
// stdenv.lib.optionalAttrs stdenv.isDarwin {
|
|
preBuild = ''
|
|
sed -i 's/,--version-script=.*$/\\/' libgamin/Makefile
|
|
'';
|
|
})
|