mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-18 10:56:53 +00:00
146cb02542
I'm not sure why024b501907used -q 0 because even netcat-openbsd has the -N flag which IMO is the better way to shutdown the socket on EOF. Our default netcat implementation has changed once again[1] in3c3b82234aand we're now using LibreSSL's implementation, which doesn't have a -q flag. See https://github.com/NixOS/nixpkgs/pull/39634 for the pull request introducing the switch. [1]: https://github.com/NixOS/nixpkgs/pull/19982 Signed-off-by: aszlig <aszlig@nix.build> Cc: @matthewbauer, @dtzWill, @Mic92
44 lines
1.3 KiB
Nix
44 lines
1.3 KiB
Nix
# Test whether hibernation from partition works.
|
|
|
|
import ./make-test.nix (pkgs: {
|
|
name = "hibernate";
|
|
|
|
nodes = {
|
|
machine = { config, lib, pkgs, ... }: with lib; {
|
|
virtualisation.emptyDiskImages = [ config.virtualisation.memorySize ];
|
|
|
|
systemd.services.backdoor.conflicts = [ "sleep.target" ];
|
|
|
|
swapDevices = mkOverride 0 [ { device = "/dev/vdb"; } ];
|
|
|
|
networking.firewall.allowedTCPPorts = [ 4444 ];
|
|
|
|
systemd.services.listener.serviceConfig.ExecStart = "${pkgs.netcat}/bin/nc -l 4444 -k";
|
|
};
|
|
|
|
probe = { config, lib, pkgs, ...}: {
|
|
environment.systemPackages = [ pkgs.netcat ];
|
|
};
|
|
};
|
|
|
|
# 9P doesn't support reconnection to virtio transport after a hibernation.
|
|
# Therefore, machine just hangs on any Nix store access.
|
|
# To work around it we run a daemon which listens to a TCP connection and
|
|
# try to connect to it as a test.
|
|
|
|
testScript =
|
|
''
|
|
$machine->waitForUnit("multi-user.target");
|
|
$machine->succeed("mkswap /dev/vdb");
|
|
$machine->succeed("swapon -a");
|
|
$machine->startJob("listener");
|
|
$machine->waitForOpenPort(4444);
|
|
$machine->succeed("systemctl hibernate &");
|
|
$machine->waitForShutdown;
|
|
$machine->start;
|
|
$probe->waitForUnit("network.target");
|
|
$probe->waitUntilSucceeds("echo test | nc machine 4444 -N");
|
|
'';
|
|
|
|
})
|