mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-25 03:17:13 +00:00
3e695874e2
* openjdk: Keep {include,man} in $out/lib/opendjk.
This is a standard layout that some JDK consumers expect.
* openjdk/8: Improve clarity of some symlink commands with terminating slash.
240 lines
8.1 KiB
Nix
240 lines
8.1 KiB
Nix
{ stdenv, fetchurl, cpio, pkgconfig, file, which, unzip, zip, xorg, cups, freetype
|
|
, alsaLib, bootjdk, cacert, perl, liberation_ttf, fontconfig, zlib
|
|
, setJavaClassPath
|
|
, minimal ? false
|
|
, enableInfinality ? true # font rendering patch
|
|
}:
|
|
|
|
let
|
|
|
|
/**
|
|
* The JRE libraries are in directories that depend on the CPU.
|
|
*/
|
|
architecture =
|
|
if stdenv.system == "i686-linux" then
|
|
"i386"
|
|
else if stdenv.system == "x86_64-linux" then
|
|
"amd64"
|
|
else
|
|
throw "openjdk requires i686-linux or x86_64 linux";
|
|
|
|
update = "122";
|
|
build = "00";
|
|
baseurl = "http://hg.openjdk.java.net/jdk8u/jdk8u";
|
|
repover = "jdk8u${update}-b${build}";
|
|
paxflags = if stdenv.isi686 then "msp" else "m";
|
|
jdk8 = fetchurl {
|
|
url = "${baseurl}/archive/${repover}.tar.gz";
|
|
sha256 = "0biy2xpb6krinmpj5pqsz0vryd2m6i819csvqnv88rc3750qh13d";
|
|
};
|
|
langtools = fetchurl {
|
|
url = "${baseurl}/langtools/archive/${repover}.tar.gz";
|
|
sha256 = "1wy9n64fvxybpd8lqd2zbiv2z23nfp10bd098lhqw7z46yxbm3ra";
|
|
};
|
|
hotspot = fetchurl {
|
|
url = "${baseurl}/hotspot/archive/${repover}.tar.gz";
|
|
sha256 = "1hzliyjaz0dq7l934d16c3ddx6kiszl2hkc2cs0rhb09m7q4zcv7";
|
|
};
|
|
corba = fetchurl {
|
|
url = "${baseurl}/corba/archive/${repover}.tar.gz";
|
|
sha256 = "0576r009my434fgv9m7lwd5bvvgbb182aw8z8fwwbi36mf5j3sr5";
|
|
};
|
|
jdk = fetchurl {
|
|
url = "${baseurl}/jdk/archive/${repover}.tar.gz";
|
|
sha256 = "1hn40jm2fcs037zx30k1gxw6j24hr50a78zjjaaql73yhhzf74xh";
|
|
};
|
|
jaxws = fetchurl {
|
|
url = "${baseurl}/jaxws/archive/${repover}.tar.gz";
|
|
sha256 = "1lbvaw3ck0inz9376qh9nw8d1ys93plfpsn1sp9mmwdjyglvznif";
|
|
};
|
|
jaxp = fetchurl {
|
|
url = "${baseurl}/jaxp/archive/${repover}.tar.gz";
|
|
sha256 = "11viwry7fj70wgzfbpslb6j1zpqqzicdf8yyqhw3whf7l6wx2bav";
|
|
};
|
|
nashorn = fetchurl {
|
|
url = "${baseurl}/nashorn/archive/${repover}.tar.gz";
|
|
sha256 = "057g393kjb9via2a3x3zm7r4g9dslw0nkwn6yppzd8hal325s1wa";
|
|
};
|
|
openjdk8 = stdenv.mkDerivation {
|
|
name = "openjdk-8u${update}b${build}";
|
|
|
|
srcs = [ jdk8 langtools hotspot corba jdk jaxws jaxp nashorn ];
|
|
sourceRoot = ".";
|
|
|
|
outputs = [ "out" "jre" ];
|
|
|
|
nativeBuildInputs = [ pkgconfig ];
|
|
buildInputs = [
|
|
cpio file which unzip zip
|
|
xorg.libX11 xorg.libXt xorg.libXext xorg.libXrender xorg.libXtst
|
|
xorg.libXi xorg.libXinerama xorg.libXcursor xorg.lndir
|
|
cups freetype alsaLib perl liberation_ttf fontconfig bootjdk zlib
|
|
];
|
|
|
|
prePatch = ''
|
|
ls | grep jdk | grep -v '^jdk8u' | awk -F- '{print $1}' | while read p; do
|
|
mv $p-* $(ls | grep '^jdk8u')/$p
|
|
done
|
|
cd $(ls | grep '^jdk8u')
|
|
'';
|
|
|
|
patches = [
|
|
./fix-java-home-jdk8.patch
|
|
./read-truststore-from-env-jdk8.patch
|
|
./currency-date-range-jdk8.patch
|
|
] ++ (if enableInfinality then [
|
|
./004_add-fontconfig.patch
|
|
./005_enable-infinality.patch
|
|
] else []);
|
|
|
|
preConfigure = ''
|
|
chmod +x configure
|
|
substituteInPlace configure --replace /bin/bash "$shell"
|
|
substituteInPlace hotspot/make/linux/adlc_updater --replace /bin/sh "$shell"
|
|
'';
|
|
|
|
configureFlags = [
|
|
"--with-boot-jdk=${bootjdk.home}"
|
|
"--with-update-version=${update}"
|
|
"--with-build-number=${build}"
|
|
"--with-milestone=fcs"
|
|
"--enable-unlimited-crypto"
|
|
"--disable-debug-symbols"
|
|
"--disable-freetype-bundling"
|
|
|
|
# glibc 2.24 deprecated readdir_r so we need this
|
|
# See https://www.mail-archive.com/openembedded-devel@lists.openembedded.org/msg49006.html
|
|
"--with-extra-cflags=\"-Wno-error=deprecated-declarations\""
|
|
] ++ (if minimal then [
|
|
"--disable-headful"
|
|
"--with-zlib=bundled"
|
|
"--with-giflib=bundled"
|
|
] else [
|
|
"--with-zlib=system"
|
|
]);
|
|
|
|
NIX_LDFLAGS= if minimal then null else "-lfontconfig";
|
|
|
|
buildFlags = "all";
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/lib/openjdk $out/share $jre/lib/openjdk
|
|
|
|
cp -av build/*/images/j2sdk-image/* $out/lib/openjdk
|
|
|
|
# Remove some broken manpages.
|
|
rm -rf $out/lib/openjdk/man/ja*
|
|
|
|
# Mirror some stuff in top-level.
|
|
mkdir $out/include $out/share/man
|
|
ln -s $out/lib/openjdk/include/* $out/include/
|
|
ln -s $out/lib/openjdk/man/* $out/share/man/
|
|
|
|
# jni.h expects jni_md.h to be in the header search path.
|
|
ln -s $out/include/linux/*_md.h $out/include/
|
|
|
|
# Remove crap from the installation.
|
|
rm -rf $out/lib/openjdk/demo $out/lib/openjdk/sample
|
|
|
|
# Move the JRE to a separate output and setup fallback fonts
|
|
mv $out/lib/openjdk/jre $jre/lib/openjdk/
|
|
mkdir $out/lib/openjdk/jre
|
|
mkdir -p $jre/lib/openjdk/jre/lib/fonts/fallback
|
|
lndir ${liberation_ttf}/share/fonts/truetype $jre/lib/openjdk/jre/lib/fonts/fallback
|
|
lndir $jre/lib/openjdk/jre $out/lib/openjdk/jre
|
|
|
|
rm -rf $out/lib/openjdk/jre/bina
|
|
ln -s $out/lib/openjdk/bin $out/lib/openjdk/jre/bin
|
|
|
|
# Make sure cmm/*.pf are not symlinks:
|
|
# https://youtrack.jetbrains.com/issue/IDEA-147272
|
|
rm -rf $out/lib/openjdk/jre/lib/cmm
|
|
ln -s {$jre,$out}/lib/openjdk/jre/lib/cmm
|
|
|
|
# Set PaX markings
|
|
exes=$(file $out/lib/openjdk/bin/* $jre/lib/openjdk/jre/bin/* 2> /dev/null | grep -E 'ELF.*(executable|shared object)' | sed -e 's/: .*$//')
|
|
echo "to mark: *$exes*"
|
|
for file in $exes; do
|
|
echo "marking *$file*"
|
|
paxmark ${paxflags} "$file"
|
|
done
|
|
|
|
# Remove duplicate binaries.
|
|
for i in $(cd $out/lib/openjdk/bin && echo *); do
|
|
if [ "$i" = java ]; then continue; fi
|
|
if cmp -s $out/lib/openjdk/bin/$i $jre/lib/openjdk/jre/bin/$i; then
|
|
ln -sfn $jre/lib/openjdk/jre/bin/$i $out/lib/openjdk/bin/$i
|
|
fi
|
|
done
|
|
|
|
# Generate certificates.
|
|
pushd $jre/lib/openjdk/jre/lib/security
|
|
rm cacerts
|
|
perl ${./generate-cacerts.pl} $jre/lib/openjdk/jre/bin/keytool ${cacert}/etc/ssl/certs/ca-bundle.crt
|
|
popd
|
|
|
|
ln -s $out/lib/openjdk/bin $out/bin
|
|
ln -s $jre/lib/openjdk/jre/bin $jre/bin
|
|
ln -s $jre/lib/openjdk/jre $out/jre
|
|
'';
|
|
|
|
# FIXME: this is unnecessary once the multiple-outputs branch is merged.
|
|
preFixup = ''
|
|
prefix=$jre stripDirs "$stripDebugList" "''${stripDebugFlags:--S}"
|
|
patchELF $jre
|
|
propagatedNativeBuildInputs+=" $jre"
|
|
|
|
# Propagate the setJavaClassPath setup hook from the JRE so that
|
|
# any package that depends on the JRE has $CLASSPATH set up
|
|
# properly.
|
|
mkdir -p $jre/nix-support
|
|
echo -n "${setJavaClassPath}" > $jre/nix-support/propagated-native-build-inputs
|
|
|
|
# Set JAVA_HOME automatically.
|
|
mkdir -p $out/nix-support
|
|
cat <<EOF > $out/nix-support/setup-hook
|
|
if [ -z "\$JAVA_HOME" ]; then export JAVA_HOME=$out/lib/openjdk; fi
|
|
EOF
|
|
'';
|
|
|
|
postFixup = ''
|
|
# Build the set of output library directories to rpath against
|
|
LIBDIRS=""
|
|
for output in $outputs; do
|
|
LIBDIRS="$(find $(eval echo \$$output) -name \*.so\* -exec dirname {} \; | sort | uniq | tr '\n' ':'):$LIBDIRS"
|
|
done
|
|
|
|
# Add the local library paths to remove dependencies on the bootstrap
|
|
for output in $outputs; do
|
|
OUTPUTDIR="$(eval echo \$$output)"
|
|
BINLIBS="$(find $OUTPUTDIR/bin/ -type f; find $OUTPUTDIR -name \*.so\*)"
|
|
echo "$BINLIBS" | while read i; do
|
|
patchelf --set-rpath "$LIBDIRS:$(patchelf --print-rpath "$i")" "$i" || true
|
|
patchelf --shrink-rpath "$i" || true
|
|
done
|
|
done
|
|
|
|
# Test to make sure that we don't depend on the bootstrap
|
|
for output in $outputs; do
|
|
if grep -q -r '${bootjdk}' $(eval echo \$$output); then
|
|
echo "Extraneous references to ${bootjdk} detected"
|
|
exit 1
|
|
fi
|
|
done
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = http://openjdk.java.net/;
|
|
license = licenses.gpl2;
|
|
description = "The open-source Java Development Kit";
|
|
maintainers = with maintainers; [ edwtjo ];
|
|
platforms = platforms.linux;
|
|
};
|
|
|
|
passthru = {
|
|
inherit architecture;
|
|
home = "${openjdk8}/lib/openjdk";
|
|
};
|
|
};
|
|
in openjdk8
|