mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-24 06:31:02 +00:00
b189247ba0
Uses the HTTPS url for cases where the existing URL has a permanent redirect. For each domain, at least one fixed derivation URL was downloaded to test the domain is properly serving downloads. Also fixes jbake source URL, which was broken.
48 lines
1.2 KiB
Nix
48 lines
1.2 KiB
Nix
{ stdenv, fetchurl, automake, autoconf, libtool, flex, bison, texinfo
|
|
|
|
# Optional Dependencies
|
|
, ncurses ? null
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "gpm-1.20.7";
|
|
|
|
src = fetchurl {
|
|
url = "https://www.nico.schottelius.org/software/gpm/archives/${name}.tar.bz2";
|
|
sha256 = "13d426a8h403ckpc8zyf7s2p5rql0lqbg2bv0454x0pvgbfbf4gh";
|
|
};
|
|
|
|
postPatch = ''
|
|
sed '1i#include <sys/types.h>' -i src/daemon/open_console.c
|
|
substituteInPlace src/prog/gpm-root.y --replace __sigemptyset sigemptyset
|
|
'';
|
|
|
|
nativeBuildInputs = [ automake autoconf libtool flex bison texinfo ];
|
|
buildInputs = [ ncurses ];
|
|
|
|
hardeningDisable = [ "format" ];
|
|
|
|
preConfigure = ''
|
|
./autogen.sh
|
|
'';
|
|
|
|
configureFlags = [
|
|
"--sysconfdir=/etc"
|
|
"--localstatedir=/var"
|
|
(if ncurses == null then "--without-curses" else "--with-curses")
|
|
];
|
|
|
|
# Provide libgpm.so for compatability
|
|
postInstall = ''
|
|
ln -sv $out/lib/libgpm.so.2 $out/lib/libgpm.so
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = https://www.nico.schottelius.org/software/gpm/;
|
|
description = "A daemon that provides mouse support on the Linux console";
|
|
license = licenses.gpl2;
|
|
platforms = platforms.linux ++ platforms.cygwin;
|
|
maintainers = with maintainers; [ eelco wkennington ];
|
|
};
|
|
}
|