mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-17 10:24:15 +00:00
54 lines
1.7 KiB
Nix
54 lines
1.7 KiB
Nix
{ stdenv, fetchurl, openssl, cyrus_sasl, db, groff, libtool }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "openldap-2.4.44";
|
|
|
|
src = fetchurl {
|
|
url = "http://www.openldap.org/software/download/OpenLDAP/openldap-release/${name}.tgz";
|
|
sha256 = "0044p20hx07fwgw2mbwj1fkx04615hhs1qyx4mawj2bhqvrnppnp";
|
|
};
|
|
|
|
# TODO: separate "out" and "bin"
|
|
outputs = [ "out" "dev" "man" "devdoc" ];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
buildInputs = [ openssl cyrus_sasl db groff libtool ];
|
|
|
|
configureFlags =
|
|
[ "--enable-overlays"
|
|
"--disable-dependency-tracking" # speeds up one-time build
|
|
"--enable-modules"
|
|
"--sysconfdir=/etc"
|
|
] ++ stdenv.lib.optional (openssl == null) "--without-tls"
|
|
++ stdenv.lib.optional (cyrus_sasl == null) "--without-cyrus-sasl"
|
|
++ stdenv.lib.optional stdenv.isFreeBSD "--with-pic";
|
|
|
|
installFlags = [ "sysconfdir=$(out)/etc" ];
|
|
|
|
# 1. Fixup broken libtool
|
|
# 2. Libraries left in the build location confuse `patchelf --shrink-rpath`
|
|
# Delete these to let patchelf discover the right path instead.
|
|
# FIXME: that one can be removed when https://github.com/NixOS/patchelf/pull/98
|
|
# is in Nixpkgs patchelf.
|
|
preFixup = ''
|
|
sed -e 's,-lsasl2,-L${cyrus_sasl.out}/lib -lsasl2,' \
|
|
-e 's,-lssl,-L${openssl.out}/lib -lssl,' \
|
|
-i $out/lib/libldap.la -i $out/lib/libldap_r.la
|
|
|
|
rm -rf $out/var
|
|
rm -r libraries/*/.libs
|
|
'';
|
|
|
|
postInstall = ''
|
|
chmod +x "$out"/lib/*.{so,dylib}
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = http://www.openldap.org/;
|
|
description = "An open source implementation of the Lightweight Directory Access Protocol";
|
|
maintainers = with maintainers; [ lovek323 mornfall ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|