mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-21 21:21:06 +00:00
68 lines
2.5 KiB
Nix
68 lines
2.5 KiB
Nix
{ lib, fetchurl, buildPythonPackage
|
|
, zip, ffmpeg, rtmpdump, phantomjs2, atomicparsley, pycryptodome, pandoc
|
|
, fetchpatch
|
|
# Pandoc is required to build the package's man page. Release tarballs contain a
|
|
# formatted man page already, though, it will still be installed. We keep the
|
|
# manpage argument in place in case someone wants to use this derivation to
|
|
# build a Git version of the tool that doesn't have the formatted man page
|
|
# included.
|
|
, generateManPage ? false
|
|
, ffmpegSupport ? true
|
|
, rtmpSupport ? true
|
|
, phantomjsSupport ? false
|
|
, hlsEncryptedSupport ? true
|
|
, makeWrapper }:
|
|
|
|
buildPythonPackage rec {
|
|
|
|
pname = "youtube-dl";
|
|
# The websites youtube-dl deals with are a very moving target. That means that
|
|
# downloads break constantly. Because of that, updates should always be backported
|
|
# to the latest stable release.
|
|
version = "2019.01.10";
|
|
|
|
src = fetchurl {
|
|
url = "https://yt-dl.org/downloads/${version}/${pname}-${version}.tar.gz";
|
|
sha256 = "07r1y06697vhbkbf8pix4cnybaqmlf1wb2df5glj2xv8nl6f51gd";
|
|
};
|
|
|
|
nativeBuildInputs = [ makeWrapper ];
|
|
buildInputs = [ zip ] ++ lib.optional generateManPage pandoc;
|
|
propagatedBuildInputs = lib.optional hlsEncryptedSupport pycryptodome;
|
|
|
|
# Ensure these utilities are available in $PATH:
|
|
# - ffmpeg: post-processing & transcoding support
|
|
# - rtmpdump: download files over RTMP
|
|
# - atomicparsley: embedding thumbnails
|
|
makeWrapperArgs = let
|
|
packagesToBinPath =
|
|
[ atomicparsley ]
|
|
++ lib.optional ffmpegSupport ffmpeg
|
|
++ lib.optional rtmpSupport rtmpdump
|
|
++ lib.optional phantomjsSupport phantomjs2;
|
|
in [ ''--prefix PATH : "${lib.makeBinPath packagesToBinPath}"'' ];
|
|
|
|
postInstall = ''
|
|
mkdir -p $out/share/zsh/site-functions
|
|
cp youtube-dl.zsh $out/share/zsh/site-functions/_youtube-dl
|
|
'';
|
|
|
|
# Requires network
|
|
doCheck = false;
|
|
|
|
meta = with lib; {
|
|
homepage = https://rg3.github.io/youtube-dl/;
|
|
repositories.git = https://github.com/rg3/youtube-dl.git;
|
|
description = "Command-line tool to download videos from YouTube.com and other sites";
|
|
longDescription = ''
|
|
youtube-dl is a small, Python-based command-line program
|
|
to download videos from YouTube.com and a few more sites.
|
|
youtube-dl is released to the public domain, which means
|
|
you can modify it, redistribute it or use it however you like.
|
|
'';
|
|
license = licenses.publicDomain;
|
|
platforms = with platforms; linux ++ darwin;
|
|
maintainers = with maintainers; [ bluescreen303 phreedom AndersonTorres fuuzetsu fpletz enzime ];
|
|
};
|
|
}
|